SARS-CoV-2-Queries

surfaces.rq

Code examples: curl

SPARQL

SELECT ?virus ?virusLabel ?work ?workLabel WITH {
  SELECT ?virus ?work WHERE {
    VALUES ?virus {
      wd:Q82069695 # SARS-CoV-2
      wd:Q16983360 # HKU1
      wd:Q16991954 # OC43
      wd:Q8351095  # NL63 
      wd:Q16983356 # 229E 
      wd:Q4902157  # MERS-CoV
      wd:Q278567   # SARS-CoV
    }
    ?work wdt:P921 ?virus ;
          wdt:P921 wd:Q484298 .
  }
} AS %ARTICLES WHERE {
  INCLUDE %ARTICLES
  SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
ORDER BY ?virusLabel ?workLabel

run or edit

Output

virus	work
Coronavírus humano 229E (edit)	Exaggerated risk of transmission of COVID-19 by fomites (edit)
Coronavírus humano 229E (edit)	Human Coronavirus 229E Remains Infectious on Common Touch Surface Materials. (edit)
Coronavírus humano 229E (edit)	Isolation and identification of human coronavirus 229E from frequently touched environmental surfaces of a university classroom that is cleaned daily (edit)
Coronavírus humano 229E (edit)	Survival of human coronaviruses 229E and OC43 in suspension and after drying on surfaces: a possible source of hospital-acquired infections (edit)
Coronavírus humano OC43 (edit)	Exaggerated risk of transmission of COVID-19 by fomites (edit)
Coronavírus humano OC43 (edit)	Survival of human coronaviruses 229E and OC43 in suspension and after drying on surfaces: a possible source of hospital-acquired infections (edit)
coronavírus da síndrome respiratória aguda grave 2 (edit)	Aerosol and Surface Stability of SARS-CoV-2 as Compared with SARS-CoV-1 (edit)
coronavírus da síndrome respiratória aguda grave 2 (edit)	Aerosol and surface stability of HCoV-19 (SARS-CoV-2) compared to SARS-CoV-1 (edit)
coronavírus da síndrome respiratória aguda grave 2 (edit)	Exaggerated risk of transmission of COVID-19 by fomites (edit)
coronavírus da síndrome respiratória do Oriente Médio (edit)	Middle East respiratory syndrome coronavirus on inanimate surfaces: A risk for health care transmission. (edit)

Code examples

curl

curl -s https://raw.githubusercontent.com/egonw/SARS-CoV-2-Queries/master/sparql/surfaces.rq | sed 's+<lang/>+pt+' > surfaces.rq

curl -H "Accept: text/tab-separated-values" -G https://query.wikidata.org/bigdata/namespace/wdq/sparql --data-urlencode query@surfaces.rq

This SPARQL query is available under CCZero.

This site is open source. Improve this page.