El número total de casos de pandemia encontrados con esta consulta:
SPARQL sparql/earthAllCasesToday.rq (ejecutar, editar)
SELECT ?numberOfCases WHERE {
wd:Q81068910 wdt:P1603 ?numberOfCases .
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} ORDER BY DESC(?numberOfCases)
Lo que nos da:
| numberOfCases |
| 312173462 |
La propagación del virus ocurre porque se transmite con demasiada facilidad de un humano a otro. Todos deben tener conocimiento de mantener una adecuada distancia, a causa de las pequeñas gotas, por ejemplo, a tos que contendrán el virus.
Pero también se encuentra que el SARS-CoV-2 sobrevive una cierta cantidad de tiempo después de ser expulsado, por ejemplo, en superficies. Podemos hacer la siguiente consulta para enumerar qué artículos vinculan los coronavirus humanos a la supervivencia en superficies planas:
SPARQL sparql/surfacesCounts.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?count WITH {
SELECT ?virus (COUNT(DISTINCT ?work) AS ?count) WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?work wdt:P921 ?virus ;
wdt:P921 wd:Q484298 .
} GROUP BY ?virus
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
ORDER BY DESC(?count)
Esto nos muestra:
| virus | count |
| Human coronavirus 229E (edit) | 4 |
| SARS-CoV-2 (edit) | 3 |
| Human coronavirus OC43 (edit) | 2 |
| MERS-CoV (edit) | 1 |
La consulta para enumerar realmente los artículos sobre supervivencia en las superficies de los virus, utiliza la siguiente consulta:
SPARQL sparql/surfaces.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?work ?workLabel WITH {
SELECT ?virus ?work WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?work wdt:P921 ?virus ;
wdt:P921 wd:Q484298 .
}
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
ORDER BY ?virusLabel ?workLabel
Lo que nos muestra para los coronavirus humanos estos artículos:
Sin embargo, podemos estar más interesados en la cantidad de casos a lo largo del tiempo. Entonces necesitamos una consulta más compleja y adecuada para calificadores de declaraciones:
SPARQL sparql/earthAllCases.rq (ejecutar, editar)
SELECT ?date ?numberOfCases WHERE {
wd:Q81068910 p:P1603 ?numberOfCasesStat .
?numberOfCasesStat ps:P1603 ?numberOfCases ;
pq:P585 ?date .
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} ORDER BY ASC(?date)
Si queremos hacer un diagrama lineal de la progresión, tenemos que cambiar ligeramente la consulta:
SPARQL sparql/earthAllCasesLinePlot.rq (ejecutar, editar)
#defaultView:LineChart
SELECT ?date ?numberOfCases WHERE {
wd:Q81068910 p:P1603 ?numberOfCasesStat .
?numberOfCasesStat ps:P1603 ?numberOfCases ;
pq:P585 ?date .
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} ORDER BY ASC(?date)
Esto nos da esta serie de tiempo:
Al igual que Wikipedia, Wikidata también tiene páginas sobre la pandemia para regiones específicas. Podemos enumerarlos con esta consulta:
SPARQL sparql/facets.rq (ejecutar, editar)
SELECT ?facet ?facetLabel WHERE {
?facet wdt:P1269 wd:Q81068910 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
La lista es muy larga y, para mostrarla, puede abrir la página SPARQL anterior.
Estas facetas se pueden usar para ver solo la progresión en una región, por ejemplo, solo los Países Bajos:
SPARQL sparql/progressionNL.rq (ejecutar, editar)
SELECT ?date ?numberOfCases WHERE {
wd:Q86756826 p:P1603 ?numberOfCasesStat .
?numberOfCasesStat ps:P1603 ?numberOfCases ;
pq:P585 ?date .
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} ORDER BY DESC(?date)
A medida que la pandemia continúa, la tabla se ha alargado y un diagrama lineal puede ser más útil:
SPARQL sparql/progressionNLlineplot.rq (ejecutar, editar)
#defaultView:LineChart
SELECT ?date ?numberOfCases WHERE {
wd:Q86756826 p:P1603 ?numberOfCasesStat .
?numberOfCasesStat ps:P1603 ?numberOfCases ;
pq:P585 ?date .
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
Que muestra:
Por supuesto, para los europeos, la situación en Italia queda grabada en nuestra memoria. Simplemente cambiamos el identificador Q de los Países Bajos por el de Italia:
SPARQL sparql/progressionIT.rq (ejecutar, editar)
SELECT ?date ?numberOfCases WHERE {
wd:Q84104992 p:P1603 ?numberOfCasesStat .
?numberOfCasesStat ps:P1603 ?numberOfCases ;
pq:P585 ?date .
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} ORDER BY DESC(?date)
Actualmente, el número total de personas infectadas es más alto en los Estados Unidos de América:
SPARQL sparql/progressionUS.rq (ejecutar, editar)
#defaultView:LineChart
SELECT ?date ?numberOfCases WHERE {
wd:Q83873577 p:P1603 ?numberOfCasesStat .
?numberOfCasesStat ps:P1603 ?numberOfCases ;
pq:P585 ?date .
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} ORDER BY DESC(?date)
Que muestra:
SPARQL sparql/graphCases.rq (ejecutar, editar)
#defaultView:LineChart
SELECT
?date ?cases
?country ?countryLabel
WHERE {
?item wdt:P31 wd:Q3241045.
?item wdt:P17 ?country.
?item p:P1603 ?casesStatement.
?casesStatement ps:P1603 ?cases.
FILTER(?cases > 0)
?casesStatement pq:P585 ?date .
{ ?item wdt:P1269 wd:Q81068910. } UNION
{ ?item wdt:P361 wd:Q83741704. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} ORDER BY ASC(?countryLabel) DESC(?date) DESC(?cases)
Esto nos muestra:
SPARQL sparql/graphDeaths.rq (ejecutar, editar)
#defaultView:LineChart
SELECT
?date ?deaths
?country ?countryLabel
WHERE {
?item wdt:P31 wd:Q3241045.
?item wdt:P17 ?country.
?item p:P1120 ?deathsStatement.
?deathsStatement ps:P1120 ?deaths.
FILTER(?deaths > 0)
?deathsStatement pq:P585 ?date .
{ ?item wdt:P1269 wd:Q81068910. } UNION
{ ?item wdt:P361 wd:Q83741704. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} ORDER BY ASC(?countryLabel) DESC(?date) DESC(?deaths)