O número total de casos na pandemia pode ser encontrado com essa busca:
SPARQL sparql/earthAllCasesToday.rq (run, edit)
SELECT ?numberOfCases WHERE {
wd:Q81068910 wdt:P1603 ?numberOfCases .
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY DESC(?numberOfCases)
O que nos dá (até o momento que o documento foi gerado):
| numberOfCases |
| 312173462 |
A propagação do vírus tão rápida ocorre por sua facilidade de pular de um humano a outro. Todos devem entender a importância de manter uma distância adequada para evitar, entre outras coisas, as gotículas projetadas pela tosse que podem carregar o vírus [citação necessária].
O SARS-CoV-2 sobrevive por algum tempo após ser expelido, por exemplo, em superfícies [citação necessária]. Podemos, com essa busca, listar artigos referentes à permanência do vírus em superficies planas:
SPARQL sparql/surfacesCounts.rq (run, edit)
SELECT ?virus ?virusLabel ?count WITH {
SELECT ?virus (COUNT(DISTINCT ?work) AS ?count) WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?work wdt:P921 ?virus ;
wdt:P921 wd:Q484298 .
} GROUP BY ?virus
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
ORDER BY DESC(?count)
Isso nos mostra:
A busca para enumerar os artigos sobre sobrevivência de quaisquer coronavírus em superfícies pode ser assim feita:
SPARQL sparql/surfaces.rq (run, edit)
SELECT ?virus ?virusLabel ?work ?workLabel WITH {
SELECT ?virus ?work WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?work wdt:P921 ?virus ;
wdt:P921 wd:Q484298 .
}
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
ORDER BY ?virusLabel ?workLabel
Para os coronavírus humanos temos esses artigos:
Podemos estar mais interessados na quantidade de casos ao longo do tempo. Então necessitamos de uma busca mais complexa, tomando em conta os qualificadores das declarações.
SPARQL sparql/earthAllCases.rq (run, edit)
SELECT ?date ?numberOfCases WHERE {
wd:Q81068910 p:P1603 ?numberOfCasesStat .
?numberOfCasesStat ps:P1603 ?numberOfCases ;
pq:P585 ?date .
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY ASC(?date)
Se quisermos fazer um gráfico linear da progressão dos casos, precisamos mudar levemente a busca:
SPARQL sparql/earthAllCasesLinePlot.rq (run, edit)
#defaultView:LineChart
SELECT ?date ?numberOfCases WHERE {
wd:Q81068910 p:P1603 ?numberOfCasesStat .
?numberOfCasesStat ps:P1603 ?numberOfCases ;
pq:P585 ?date .
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY ASC(?date)
Isso nos fornece a seguinte série temporal:
Assim como a Wikipédia, a Wikidata também contem páginas sobre a pandemia para regiões específicas. Podemos enumerá-las com essa consulta:
SPARQL sparql/facets.rq (run, edit)
SELECT ?facet ?facetLabel WHERE {
?facet wdt:P1269 wd:Q81068910 .
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
A lista é extensa, e para mostrá-la, você pode abrir a página SPARQL anterior.
As facetas podem ser usadas, por exemplo, para ver aprogressão em uma região, por exemplo, só nos Países Baixos:
SPARQL sparql/progressionNL.rq (run, edit)
SELECT ?date ?numberOfCases WHERE {
wd:Q86756826 p:P1603 ?numberOfCasesStat .
?numberOfCasesStat ps:P1603 ?numberOfCases ;
pq:P585 ?date .
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY DESC(?date)
A medida que a pandemia continua, a tabela aumentou, e um gráfico pode ser mais útil.
SPARQL sparql/progressionNLlineplot.rq (run, edit)
#defaultView:LineChart
SELECT ?date ?numberOfCases WHERE {
wd:Q86756826 p:P1603 ?numberOfCasesStat .
?numberOfCasesStat ps:P1603 ?numberOfCases ;
pq:P585 ?date .
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
Que mostra:
Para os europeus, em especial, a situação da Itália ficou marcada na nossa memória. Simplesmente podemos mudar o identificador Q dos Países Baixos por aquele da Itália:
SPARQL sparql/progressionIT.rq (run, edit)
SELECT ?date ?numberOfCases WHERE {
wd:Q84104992 p:P1603 ?numberOfCasesStat .
?numberOfCasesStat ps:P1603 ?numberOfCases ;
pq:P585 ?date .
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY DESC(?date)
Atualmente, o número total de casos confirmados de pessoas infectadas é mais alto nos Estados Unidos de América que em qualquer outro país do mundo.
SPARQL sparql/progressionUS.rq (run, edit)
#defaultView:LineChart
SELECT ?date ?numberOfCases WHERE {
wd:Q83873577 p:P1603 ?numberOfCasesStat .
?numberOfCasesStat ps:P1603 ?numberOfCases ;
pq:P585 ?date .
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY DESC(?date)
Que mostra:
SPARQL sparql/graphCases.rq (run, edit)
#defaultView:LineChart
SELECT
?date ?cases
?country ?countryLabel
WHERE {
?item wdt:P31 wd:Q3241045.
?item wdt:P17 ?country.
?item p:P1603 ?casesStatement.
?casesStatement ps:P1603 ?cases.
FILTER(?cases > 0)
?casesStatement pq:P585 ?date .
{ ?item wdt:P1269 wd:Q81068910. } UNION
{ ?item wdt:P361 wd:Q83741704. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY ASC(?countryLabel) DESC(?date) DESC(?cases)
Isto nos mostra:
SPARQL sparql/graphDeaths.rq (run, edit)
#defaultView:LineChart
SELECT
?date ?deaths
?country ?countryLabel
WHERE {
?item wdt:P31 wd:Q3241045.
?item wdt:P17 ?country.
?item p:P1120 ?deathsStatement.
?deathsStatement ps:P1120 ?deaths.
FILTER(?deaths > 0)
?deathsStatement pq:P585 ?date .
{ ?item wdt:P1269 wd:Q81068910. } UNION
{ ?item wdt:P361 wd:Q83741704. }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY ASC(?countryLabel) DESC(?date) DESC(?deaths)