Estas consultas enumeran los últimos 10 artículos sobre una serie de temas. No reemplaza a Scholia [1], que tiene una visión mucho más rica de la literatura sobre el tema. Cada sección incluye un enlace a la página de Scholia para ese tema. Las consultas utilizadas aquí son muy básicas y solo utilizan la propiedad ‘sujeto principal’.
SARS-CoV-2 es el nombre del virus.
SPARQL sparql/litSARSCoV2.rq (ejecutar, editar)
SELECT (MAX(?dates) as ?date) ?work ?workLabel ?doi WHERE {
?work wdt:P921 wd:Q82069695 .
OPTIONAL { ?work wdt:P577 ?dates . }
OPTIONAL { ?work wdt:P356 ?doi . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} GROUP BY ?work ?workLabel ?doi ORDER BY DESC(?date) ?work
Esto le da estos 10 documentos:
También podemos consultar artículos sobre los genes:
SPARQL sparql/litSARSCoV2Genes.rq (ejecutar, editar)
SELECT (MAX(?dates) as ?date) ?work ?workLabel ?doi WHERE {
?gene wdt:P703 wd:Q82069695 ; wdt:P31 wd:Q7187 .
?work wdt:P921 ?gene .
OPTIONAL { ?work wdt:P577 ?dates . }
OPTIONAL { ?work wdt:P356 ?doi . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} GROUP BY ?work ?workLabel ?doi ORDER BY DESC(?date)
Que actualmente da:
Y sobre las proteínas del virus:
SPARQL sparql/litSARSCoV2Proteins.rq (ejecutar, editar)
SELECT (MAX(?dates) as ?date) ?work ?workLabel ?doi WHERE {
?protein wdt:P703 wd:Q82069695 ; wdt:P31 wd:Q8054 .
?work wdt:P921 ?protein .
OPTIONAL { ?work wdt:P577 ?dates . }
OPTIONAL { ?work wdt:P356 ?doi . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} GROUP BY ?work ?workLabel ?doi ORDER BY DESC(?date)
Que actualmente da:
Como se describe en el capítulo ??, el SARS-Cov-2 es uno de los coronavirus que puede infectar a los humanos.
SPARQL sparql/litCoronaviruses.rq (ejecutar, editar)
SELECT (MAX(?dates) as ?date) ?work ?workLabel ?doi WHERE {
?work wdt:P921 wd:Q57751738 .
OPTIONAL { ?work wdt:P577 ?dates . }
OPTIONAL { ?work wdt:P356 ?doi . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} GROUP BY ?work ?workLabel ?doi ORDER BY DESC(?date)
Esto le da estos 10 documentos:
Hay más de 6000 artículos sobre los siete coronavirus humanos en Wikidata. Por lo tanto, la siguiente consulta está un poco ajustada para el rendimiento y es más compleja. Además, la lista es bastante larga y no figura en esta página.
Para ver el resultado, haga clic a continuación en el nombre del archivo litHumanCoronaviruses.rq:
SPARQL sparql/litHumanCoronaviruses.rq (ejecutar, editar)
SELECT ?date ?work ?workLabel ?virus ?virusLabel ?doi ?pubmed WITH {
SELECT (MAX(?dates) as ?date) ?work ?doi ?virus WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?work wdt:P577 ?dates ;
wdt:P921 ?virus .
} GROUP BY ?work ?doi ?virus
ORDER BY DESC(?date)
LIMIT 5000
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
OPTIONAL { ?work wdt:P356 ?doi . }
OPTIONAL { ?work wdt:P698 ?pubmed . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
ORDER BY DESC(?date) ?doi ?pubmed ?virus
Además, el número de artículos para cada virus varía significativamente, lo que se puede visualizar con esta consulta:
SPARQL sparql/litHumanCoronavirusesCounts.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?count WITH {
SELECT ?virus (COUNT(DISTINCT ?work) AS ?count) WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?work wdt:P921 ?virus .
} GROUP BY ?virus
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
ORDER BY DESC(?count)
Lo que nos dice:
| virus | count |
| SARS-CoV-2 (edit) | 24131 |
| SARS coronavirus (edit) | 2487 |
| MERS-CoV (edit) | 1051 |
| Human coronavirus OC43 (edit) | 114 |
| Human coronavirus 229E (edit) | 107 |
| Coronavirus Humana NL63 (edit) | 94 |
| Human coronavirus HKU1 (edit) | 22 |
SPARQL sparql/litHumanCoronavirusesGeneCounts.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?gene ?geneLabel ?count WITH {
SELECT ?virus ?gene (COUNT(DISTINCT ?work) AS ?count) WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?gene wdt:P703 ?virus ; wdt:P31 wd:Q7187 .
?work wdt:P921 ?gene .
} GROUP BY ?virus ?gene
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
ORDER BY DESC(?count)
Lo que nos muestra:
SPARQL sparql/litHumanCoronavirusesProteinCounts.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?protein ?proteinLabel ?count WITH {
SELECT ?virus ?protein (COUNT(DISTINCT ?work) AS ?count) WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?protein wdt:P31 wd:Q8054 .
{ ?protein wdt:P703 ?virus }
UNION
{ ?protein wdt:P702 | ^wdt:P688 ?gene . ?gene wdt:P703 ?virus }
?work wdt:P921 ?protein .
} GROUP BY ?virus ?protein
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
ORDER BY DESC(?count) ?virus ?protein
Donde están los recuentos: