SARS-CoV-2-Queries

[ en ja es pt ]

Literatura

Estas consultas enumeran los últimos 10 artículos sobre una serie de temas. No reemplaza a Scholia [1], que tiene una visión mucho más rica de la literatura sobre el tema. Cada sección incluye un enlace a la página de Scholia para ese tema. Las consultas utilizadas aquí son muy básicas y solo utilizan la propiedad ‘sujeto principal’.

Literatura sobre SARS-CoV-2

SARS-CoV-2 es el nombre del virus.

SPARQL sparql/litSARSCoV2.rq (ejecutar, editar)

SELECT (MAX(?dates) as ?date) ?work ?workLabel ?doi WHERE {
  ?work wdt:P921 wd:Q82069695 .
  OPTIONAL { ?work wdt:P577 ?dates . }
  OPTIONAL { ?work wdt:P356 ?doi . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} GROUP BY ?work ?workLabel ?doi ORDER BY DESC(?date) ?work

Esto le da estos 10 documentos:

date work doi
2021-06-01 The fate of SARS-COV-2 in WWTPS points out the sludge line as a suitable spot for detection of COVID-19 (edit) 10.1016/J.SCITOTENV.2021.145268
2021-06-01 Conflicting and ambiguous names of overlapping ORFs in the SARS-CoV-2 genome: A homology-based resolution (edit) 10.1016/J.VIROL.2021.02.013
2021-06-01 Rare mutations in the accessory proteins ORF6, ORF7b, and ORF10 of the SARS-CoV-2 genomes (edit) 10.1016/J.MGENE.2021.100873
2021-06-01 Mutational analysis of SARS-CoV-2 during six months of COVID-19 pandemic (edit) 10.1016/J.GENREP.2021.101024
2021-04-23 ORF8 contributes to cytokine storm during SARS-CoV-2 infection by activating IL-17 pathway (edit) 10.1016/J.ISCI.2021.102293
2021-04-23 SARS-CoV-2 variants combining spike mutations and the absence of ORF8 may be more transmissible and require close monitoring (edit) 10.1016/J.BBRC.2021.02.080
2021-04-16 The Mechanism of SARS-CoV-2 Nucleocapsid Protein Recognition by the Human 14-3-3 Proteins (edit) 10.1016/J.JMB.2021.166875
2021-04-01 Crystallographic molecular replacement using an in silico-generated search model of SARS-CoV-2 ORF8 (edit) 10.1002/PRO.4050
This table is truncated. See the full table at sparql/litSARSCoV2.rq

Literatura sobre SARS-CoV-2 genes

También podemos consultar artículos sobre los genes:

SPARQL sparql/litSARSCoV2Genes.rq (ejecutar, editar)

SELECT (MAX(?dates) as ?date) ?work ?workLabel ?doi WHERE {
  ?gene wdt:P703 wd:Q82069695 ; wdt:P31 wd:Q7187 .
  ?work wdt:P921 ?gene .
  OPTIONAL { ?work wdt:P577 ?dates . }
  OPTIONAL { ?work wdt:P356 ?doi . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} GROUP BY ?work ?workLabel ?doi ORDER BY DESC(?date)

Que actualmente da:

date work doi
2020-08-18 Effects of a major deletion in the SARS-CoV-2 genome on the severity of infection and the inflammatory response: an observational cohort study (edit) 10.1016/S0140-6736(20)31757-8
2020-07-21 Discovery and Genomic Characterization of a 382-Nucleotide Deletion in ORF7b and ORF8 during the Early Evolution of SARS-CoV-2 (edit) 10.1128/MBIO.01610-20
2020-06-22 A neutralizing human antibody binds to the N-terminal domain of the Spike protein of SARS-CoV-2 (edit) 10.1126/SCIENCE.ABC6952
2020-06-16 SARS-CoV-2 genomic surveillance in Taiwan revealed novel ORF8-deletion mutant and clade possibly associated with infections in Middle East (edit) 10.1080/22221751.2020.1782271
2020-05-25 Genomic surveillance of SARS-CoV-2 in Thailand reveals mixed imported populations, a local lineage expansion and a virus with truncated ORF7a (edit) 10.1101/2020.05.22.20108498
2020-05-18 Molecular conservation and Differential mutation on ORF3a gene in Indian SARS-CoV2 genomes (edit) 10.1101/2020.05.14.096107
2020-04-30 A SARS-CoV-2 protein interaction map reveals targets for drug repurposing (edit) 10.1038/S41586-020-2286-9
2020-04-20 Crystal structure of SARS-CoV-2 nucleocapsid protein RNA binding domain reveals potential unique drug targeting sites (edit) 10.1016/J.APSB.2020.04.009
This table is truncated. See the full table at sparql/litSARSCoV2Genes.rq

Literatura sobre SARS-CoV-2 proteínas

Y sobre las proteínas del virus:

SPARQL sparql/litSARSCoV2Proteins.rq (ejecutar, editar)

SELECT (MAX(?dates) as ?date) ?work ?workLabel ?doi WHERE {
  ?protein wdt:P703 wd:Q82069695 ; wdt:P31 wd:Q8054 .
  ?work wdt:P921 ?protein .
  OPTIONAL { ?work wdt:P577 ?dates . }
  OPTIONAL { ?work wdt:P356 ?doi . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} GROUP BY ?work ?workLabel ?doi ORDER BY DESC(?date)

Que actualmente da:

date work doi
2021-04-23 ORF8 contributes to cytokine storm during SARS-CoV-2 infection by activating IL-17 pathway (edit) 10.1016/J.ISCI.2021.102293
2021-04-16 The Mechanism of SARS-CoV-2 Nucleocapsid Protein Recognition by the Human 14-3-3 Proteins (edit) 10.1016/J.JMB.2021.166875
2021-04-01 Crystallographic molecular replacement using an in silico-generated search model of SARS-CoV-2 ORF8 (edit) 10.1002/PRO.4050
2021-04-01 The ORF8 protein of SARS-CoV-2 induced endoplasmic reticulum stress and mediated immune evasion by antagonizing production of interferon beta (edit) 10.1016/J.VIRUSRES.2021.198350
2021-03-25 Characterization of SARS-CoV-2 proteins reveals Orf6 pathogenicity, subcellular localization, host interactions and attenuation by Selinexor (edit) 10.1186/S13578-021-00568-7
2021-03-24 Arginine Methylation Regulates SARS-CoV-2 Nucleocapsid Protein Function and Viral Replication (edit) 10.1101/2021.03.24.436822
2021-03-23 SARS-CoV-2 variants lacking ORF8 occurred in farmed mink and pangolin (edit) 10.1016/J.GENE.2021.145596
2021-03-15 SARS-CoV-2 Nsp8 N-terminal domain dimerizes and harbors autonomously folded elements (edit) 10.1101/2021.03.12.435186
This table is truncated. See the full table at sparql/litSARSCoV2Proteins.rq

Literatura sobre los coronavirus

Como se describe en el capítulo ??, el SARS-Cov-2 es uno de los coronavirus que puede infectar a los humanos.

SPARQL sparql/litCoronaviruses.rq (ejecutar, editar)

SELECT (MAX(?dates) as ?date) ?work ?workLabel ?doi WHERE {
  ?work wdt:P921 wd:Q57751738 .
  OPTIONAL { ?work wdt:P577 ?dates . }
  OPTIONAL { ?work wdt:P356 ?doi . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} GROUP BY ?work ?workLabel ?doi ORDER BY DESC(?date)

Esto le da estos 10 documentos:

date work doi
2020-04-01 [Recommendations for critically ill patients with COVID-19] (edit) 10.1007/S00063-020-00674-3
2020-03-27 A new threat from an old enemy: Re‑emergence of coronavirus (Review) (edit) 10.3892/IJMM.2020.4555
2020-02-26 Potential Rapid Diagnostics, Vaccine and Therapeutics for 2019 Novel Coronavirus (2019-nCoV): A Systematic Review (edit) 10.3390/JCM9030623
2020-02-14 The First Disease X is Caused by a Highly Transmissible Acute Respiratory Syndrome Coronavirus (edit) 10.1007/S12250-020-00206-5

Literatura sobre los coronavirus humanos

Hay más de 6000 artículos sobre los siete coronavirus humanos en Wikidata. Por lo tanto, la siguiente consulta está un poco ajustada para el rendimiento y es más compleja. Además, la lista es bastante larga y no figura en esta página. Para ver el resultado, haga clic a continuación en el nombre del archivo litHumanCoronaviruses.rq:

SPARQL sparql/litHumanCoronaviruses.rq (ejecutar, editar)

SELECT ?date ?work ?workLabel ?virus ?virusLabel ?doi ?pubmed WITH {
  SELECT (MAX(?dates) as ?date) ?work ?doi ?virus WHERE {
    VALUES ?virus {
      wd:Q82069695 # SARS-CoV-2
      wd:Q16983360 # HKU1
      wd:Q16991954 # OC43
      wd:Q8351095  # NL63 
      wd:Q16983356 # 229E 
      wd:Q4902157  # MERS-CoV
      wd:Q278567   # SARS-CoV
    }
    ?work wdt:P577 ?dates ;
          wdt:P921 ?virus .
  } GROUP BY ?work ?doi ?virus
    ORDER BY DESC(?date)
    LIMIT 5000
} AS %ARTICLES WHERE {
  INCLUDE %ARTICLES
  OPTIONAL { ?work wdt:P356 ?doi . }
  OPTIONAL { ?work wdt:P698 ?pubmed . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
ORDER BY DESC(?date) ?doi ?pubmed ?virus

Además, el número de artículos para cada virus varía significativamente, lo que se puede visualizar con esta consulta:

SPARQL sparql/litHumanCoronavirusesCounts.rq (ejecutar, editar)

SELECT ?virus ?virusLabel ?count WITH {
  SELECT ?virus (COUNT(DISTINCT ?work) AS ?count) WHERE {
    VALUES ?virus {
      wd:Q82069695 # SARS-CoV-2
      wd:Q16983360 # HKU1
      wd:Q16991954 # OC43
      wd:Q8351095  # NL63 
      wd:Q16983356 # 229E 
      wd:Q4902157  # MERS-CoV
      wd:Q278567   # SARS-CoV
    }
    ?work wdt:P921 ?virus .
  } GROUP BY ?virus
} AS %ARTICLES WHERE {
  INCLUDE %ARTICLES
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
ORDER BY DESC(?count)

Lo que nos dice:

virus count
SARS-CoV-2 (edit) 18543
SARS coronavirus (edit) 2481
MERS-CoV (edit) 1042
Human coronavirus OC43 (edit) 91
Human coronavirus 229E (edit) 84
Coronavirus Humana NL63 (edit) 79
Human coronavirus HKU1 (edit) 21

y sus genes

SPARQL sparql/litHumanCoronavirusesGeneCounts.rq (ejecutar, editar)

SELECT ?virus ?virusLabel ?gene ?geneLabel ?count WITH {
  SELECT ?virus ?gene (COUNT(DISTINCT ?work) AS ?count) WHERE {
    VALUES ?virus {
      wd:Q82069695 # SARS-CoV-2
      wd:Q16983360 # HKU1
      wd:Q16991954 # OC43
      wd:Q8351095  # NL63 
      wd:Q16983356 # 229E 
      wd:Q4902157  # MERS-CoV
      wd:Q278567   # SARS-CoV
    }
    ?gene wdt:P703 ?virus ; wdt:P31 wd:Q7187 .
    ?work wdt:P921 ?gene .
  } GROUP BY ?virus ?gene
} AS %ARTICLES WHERE {
  INCLUDE %ARTICLES
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
ORDER BY DESC(?count)

Lo que nos muestra:

virus gene count
SARS-CoV-2 (edit) ORF8 protein (edit) 6
Coronavirus Humana NL63 (edit) membrane protein (edit) 3
Coronavirus Humana NL63 (edit) nucleocapsid protein (edit) 3
Coronavirus Humana NL63 (edit) envelope protein (edit) 3
Coronavirus Humana NL63 (edit) Gen coronavirus humano NL63 (edit) 3
Coronavirus Humana NL63 (edit) replicase polyprotein 1ab (edit) 2
Coronavirus Humana NL63 (edit) protein 3 (edit) 2
Human coronavirus 229E (edit) nucleocapsid protein (edit) 2
Human coronavirus 229E (edit) surface glycoprotein (edit) 2
Human coronavirus OC43 (edit) spike surface glycoprotein (edit) 2
SARS-CoV-2 (edit) nucleocapsid phosphoprotein (edit) 2
SARS-CoV-2 (edit) ORF7b (edit) 2
SARS-CoV-2 (edit) ORF3a protein (edit) 2
SARS-CoV-2 (edit) surface glycoprotein (edit) 2
Human coronavirus 229E (edit) envelope protein (edit) 1
Human coronavirus 229E (edit) membrane protein (edit) 1
Human coronavirus 229E (edit) 4b protein (edit) 1
Human coronavirus 229E (edit) 4a protein (edit) 1
Human coronavirus OC43 (edit) membrane protein (edit) 1
Human coronavirus OC43 (edit) I protein;nucleocapsid protein (edit) 1
Human coronavirus OC43 (edit) ns2 (edit) 1
Human coronavirus HKU1 (edit) membrane glycoprotein (edit) 1
Human coronavirus HKU1 (edit) hemagglutinin-esterase glycoprotein (edit) 1
Human coronavirus HKU1 (edit) ORF1a polyprotein;ORF1ab polyprotein (edit) 1
Human coronavirus HKU1 (edit) nucleocapsid phosphoprotein (edit) 1
Human coronavirus HKU1 (edit) envelope protein (edit) 1
Human coronavirus HKU1 (edit) spike glycoprotein (edit) 1
SARS-CoV-2 (edit) ORF7a protein (edit) 1
SARS-CoV-2 (edit) membrane glycoprotein (edit) 1
SARS-CoV-2 (edit) envelope protein (edit) 1
SARS-CoV-2 (edit) ORF1a polyprotein;ORF1ab polyprotein (edit) 1

y sus proteínas

SPARQL sparql/litHumanCoronavirusesProteinCounts.rq (ejecutar, editar)

SELECT ?virus ?virusLabel ?protein ?proteinLabel ?count WITH {
  SELECT ?virus ?protein (COUNT(DISTINCT ?work) AS ?count) WHERE {
    VALUES ?virus {
      wd:Q82069695 # SARS-CoV-2
      wd:Q16983360 # HKU1
      wd:Q16991954 # OC43
      wd:Q8351095  # NL63 
      wd:Q16983356 # 229E 
      wd:Q4902157  # MERS-CoV
      wd:Q278567   # SARS-CoV
    }
    ?protein wdt:P31 wd:Q8054 .
    { ?protein wdt:P703 ?virus }
    UNION
    { ?protein wdt:P702 | ^wdt:P688 ?gene . ?gene wdt:P703 ?virus }
    ?work wdt:P921 ?protein .
  } GROUP BY ?virus ?protein
} AS %ARTICLES WHERE {
  INCLUDE %ARTICLES
  SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
ORDER BY DESC(?count) ?virus ?protein

Donde están los recuentos:

virus protein count
SARS-CoV-2 (edit) spike glycoprotein [SARS-CoV-2] (edit) 104
SARS coronavirus (edit) spike glycoprotein [SARS-Cov] (edit) 83
SARS coronavirus (edit) nucleoprotein [SARS-Cov] (edit) 60
SARS coronavirus (edit) 3C-like proteinase [SARS-Cov] (edit) 57
SARS-CoV-2 (edit) nucleocapsid protein [SARS-CoV-2] (edit) 48
SARS coronavirus (edit) Protein 3a [SARS-Cov] (edit) 39
SARS coronavirus (edit) papain-like proteinase [SARS-Cov] (edit) 38
SARS coronavirus (edit) Envelope small membrane protein [SARS-Cov] (edit) 36
SARS-CoV-2 (edit) Papain-like proteinase [SARS-CoV-2] (edit) 28
SARS-CoV-2 (edit) Host translation inhibitor nsp1 [SARS-CoV-2] (edit) 28
SARS-CoV-2 (edit) non-structural protein 16 [SARS-CoV-2] (edit) 26
SARS-CoV-2 (edit) Non-structural protein 10 [SARS CoV-2] (edit) 25
SARS-CoV-2 (edit) RNA-directed RNA polymerase [SARS-CoV-2] (edit) 25
SARS-CoV-2 (edit) non-structural protein 5 [SARS-CoV-2] (edit) 24
SARS coronavirus (edit) Membrane protein [SARS-Cov] (edit) 23
SARS-CoV-2 (edit) ORF8 protein [SARS-CoV-2] (edit) 20
SARS-CoV-2 (edit) Helicase [SARS-CoV-2] (edit) 17
SARS coronavirus (edit) Non-structural protein NS6 [SARS-Cov] (edit) 15
SARS coronavirus (edit) Protein 7a [SARS-Cov] (edit) 14
SARS-CoV-2 (edit) non-structural protein 15 [SARS-CoV-2] (edit) 14
SARS-CoV-2 (edit) Non-structural protein 14 [SARS-CoV-2] (edit) 13
SARS-CoV-2 (edit) Non-structural protein nsp8 [SARS-CoV-2] (edit) 13
SARS coronavirus (edit) host translation inhibitor nsp1 [SARS-Cov] (edit) 12
SARS-CoV-2 (edit) Non-structural protein 7 [SARS-CoV-2] (edit) 11
SARS coronavirus (edit) Guanine-N7 methyltransferase [SARS-Cov] (edit) 10
SARS coronavirus (edit) protein non-structural 8a [SARS-Cov] (edit) 10
MERS-CoV (edit) spike glycoprotein (edit) 10
SARS coronavirus (edit) Non-structural protein 3b [SARS-Cov] (edit) 9
SARS coronavirus (edit) 2'-O-methyltransferase [SARS-Cov] (edit) 9
SARS-CoV-2 (edit) envelope protein [SARS-CoV-2] (edit) 9
SARS-CoV-2 (edit) Protein 7a [SARS-CoV-2] (edit) 9
SARS coronavirus (edit) Protein 9b [SARS-Cov] (edit) 8
SARS coronavirus (edit) uridylate-specific endoribonuclease [SARS-Cov] (edit) 8
SARS coronavirus (edit) protein non-structural 8b [SARS-Cov] (edit) 8
SARS-CoV-2 (edit) membrane protein [SARS-CoV-2] (edit) 8
SARS-CoV-2 (edit) ORF6 protein [SARS-CoV-2] (edit) 8
SARS-CoV-2 (edit) Non-structural protein 9 [SARS-CoV-2] (edit) 8
SARS coronavirus (edit) non-structural protein 10 [SARS-Cov] (edit) 7
SARS coronavirus (edit) RNA-directed RNA polymerase [SARS-Cov] (edit) 7
SARS coronavirus (edit) helicase [SARS-Cov] (edit) 7
SARS-CoV-2 (edit) Viroporin 3a [SARS-CoV-2] (edit) 7
SARS-CoV-2 (edit) Non-structural protein 2 [SARS CoV-2] (edit) 7
SARS coronavirus (edit) replicase polyprotein 1ab [SARS-Cov] (edit) 6
SARS coronavirus (edit) non-structural protein 7 [SARS-Cov] (edit) 6
SARS coronavirus (edit) non-structural protein 8 [SARS-Cov] (edit) 6
Human coronavirus OC43 (edit) nucleocapsid protein (edit) 5
SARS coronavirus (edit) Protein non-structural 7b [SARS-Cov] (edit) 5
SARS coronavirus (edit) non-structural protein 9 [SARS-Cov] (edit) 5
SARS-CoV-2 (edit) ORF3b protein [SARS-CoV-2] (edit) 5
SARS-CoV-2 (edit) non-structural protein 6 [SARS-CoV-2] (edit) 5
SARS-CoV-2 (edit) Protein ORF9b [SARS-CoV-2] (edit) 5
Coronavirus Humana NL63 (edit) Spike glycoprotein [NL63] (edit) 5
Human coronavirus OC43 (edit) spike surface glycoprotein (edit) 4
SARS coronavirus (edit) non-structural protein 4 [SARS-Cov] (edit) 4
SARS-CoV-2 (edit) ORF10 protein [SARS-CoV-2] (edit) 4
Human coronavirus HKU1 (edit) Spike glycoprotein (edit) 3
SARS coronavirus (edit) non-structural protein 6 [SARS-Cov] (edit) 3
MERS-CoV (edit) nucleoprotein (edit) 3
SARS-CoV-2 (edit) Protein non-structural 7b [SARS-CoV-2] (edit) 3
SARS-CoV-2 (edit) Non-structural protein 4 [SARS-CoV-2] (edit) 3
Human coronavirus 229E (edit) Non-structural protein 4b (edit) 2
Human coronavirus 229E (edit) Spike glycoprotein (edit) 2
Human coronavirus HKU1 (edit) Replicase polyprotein 1ab (edit) 2
Human coronavirus OC43 (edit) ns12.9 (edit) 2
Human coronavirus OC43 (edit) hemagglutinin-esterase (edit) 2
SARS coronavirus (edit) non-structural protein 2 [SARS-Cov] (edit) 2
SARS-CoV-2 (edit) orf1ab polyprotein [SARS-Cov 2] (edit) 2
Coronavirus Humana NL63 (edit) Nucleoprotein (edit) 2
Human coronavirus 229E (edit) Non-structural protein 4a (edit) 1
Human coronavirus 229E (edit) Nucleoprotein (edit) 1
Human coronavirus 229E (edit) Replicase polyprotein 1ab (edit) 1
Human coronavirus HKU1 (edit) Spike glycoprotein (edit) 1
Human coronavirus HKU1 (edit) Membrane protein (edit) 1
Human coronavirus OC43 (edit) ns2 (edit) 1
Human coronavirus OC43 (edit) membrane protein (edit) 1
SARS coronavirus (edit) spike protein S2 [SARS-Cov] (edit) 1
SARS coronavirus (edit) Replicase polyprotein 1a (edit) 1
MERS-CoV (edit) NS4B protein (edit) 1
SARS-CoV-2 (edit) putative protein ORF3c (edit) 1
SARS-CoV-2 (edit) Non-structural protein 11 [SARS CoV-2] (edit) 1
SARS-CoV-2 (edit) ORF9c protein [SARS CoV-2] (edit) 1
Coronavirus Humana NL63 (edit) Membrane protein (edit) 1

Referencias

  1. Rasberry L, Willighagen E, Nielsen FÅ, Mietchen D. Robustifying Scholia: paving the way for knowledge discovery and research assessment through Wikidata. RIO Journal [Internet]. 2019 May 2;5. Available from: https://riojournal.com/article/35820/ doi:10.3897/RIO.5.E35820 (Scholia)