SARS-CoV-2-Queries

[ en ja es pt ]

文献

これらのクエリはいくつかの課題に関する最新10件分の記事を取得します。これは、 Scholia [1]とは異なります。Scholiaは特定の課題について遥かに豊かな文献の概要が得られます。各節ではScholiaへのリンクを含めています。ここでのクエリはとても基本的なもので、「主題」プロパティのみを利用します。

SARS-CoV-2について

SARS-CoV-2がこのウイルスの名前です。

SPARQL sparql/litSARSCoV2.rq (実行, 編集)

SELECT (MAX(?dates) as ?date) ?work ?workLabel ?doi WHERE {
  ?work wdt:P921 wd:Q82069695 .
  OPTIONAL { ?work wdt:P577 ?dates . }
  OPTIONAL { ?work wdt:P356 ?doi . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
} GROUP BY ?work ?workLabel ?doi ORDER BY DESC(?date) ?work

結果として10件の論文を得ます。

date work doi
2023-09-01 Kaempferol inhibits SARS-CoV-2 invasion by impairing heptad repeats-mediated viral fusion (edit) 10.1016/J.PHYMED.2023.154942
2023-06-01 Head and neck reconstruction in the SARS-CoV-2 pandemic era: outcomes and lessons learned (edit) 10.21037/FOMM-21-4
2023-06-01 Uptake and effectiveness of a mobile application for real-time reporting and quality assurance of decentralized SARS-CoV-2 testing in Uganda (edit) 10.3389/FPUBH.2023.1053544
2023-05-31 Single-cell analysis of adult human heart across healthy and cardiovascular disease patients reveals the cellular landscape underlying SARS-CoV-2 invasion of myocardial tissue through ACE2 (edit) 10.1186/S12967-023-04224-1
2023-05-18 Impact of peptide:HLA complex stability for the identification of SARS-CoV-2-specific CD8+T cells (edit) 10.3389/FIMMU.2023.1151659
2023-05-08 Excess risk of SARS-CoV-2 infection among in-person nonhealthcare workers in six states, September 2020-June 2021 (edit) 10.1002/AJIM.23487
2023-04-19 Seroprevalence and SARS-CoV-2 invasion in general populations: A scoping review over the first year of the pandemic (edit) 10.1371/JOURNAL.PONE.0269104
2023-04-03 Oral Supplementation with AHCC, a Standardized Extract of Cultured Mycelia, Enhances Host Resistance against SARS-CoV-2 Infection (edit) 10.3390/PATHOGENS12040554
This table is truncated. See the full table at sparql/litSARSCoV2.rq

SARS-CoV-2遺伝子について

遺伝子についても文献を検索できます。

SPARQL sparql/litSARSCoV2Genes.rq (実行, 編集)

SELECT (MAX(?dates) as ?date) ?work ?workLabel ?doi WHERE {
  ?gene wdt:P703 wd:Q82069695 ; wdt:P31 wd:Q7187 .
  ?work wdt:P921 ?gene .
  OPTIONAL { ?work wdt:P577 ?dates . }
  OPTIONAL { ?work wdt:P356 ?doi . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
} GROUP BY ?work ?workLabel ?doi ORDER BY DESC(?date)

これにより、現在以下の結果を得ます。

date work doi
2021-01-01 SARS-CoV-2 Accessory Protein ORF7b Mediates Tumor Necrosis Factor-α-Induced Apoptosis in Cells (edit) 10.3389/FMICB.2021.654709
2020-08-18 Effects of a major deletion in the SARS-CoV-2 genome on the severity of infection and the inflammatory response: an observational cohort study (edit) 10.1016/S0140-6736(20)31757-8
2020-07-21 Discovery and Genomic Characterization of a 382-Nucleotide Deletion in ORF7b and ORF8 during the Early Evolution of SARS-CoV-2 (edit) 10.1128/MBIO.01610-20
2020-06-22 A neutralizing human antibody binds to the N-terminal domain of the Spike protein of SARS-CoV-2 (edit) 10.1126/SCIENCE.ABC6952
2020-06-16 SARS-CoV-2 genomic surveillance in Taiwan revealed novel ORF8-deletion mutant and clade possibly associated with infections in Middle East (edit) 10.1080/22221751.2020.1782271
2020-05-25 Genomic surveillance of SARS-CoV-2 in Thailand reveals mixed imported populations, a local lineage expansion and a virus with truncated ORF7a (edit) 10.1101/2020.05.22.20108498
2020-05-18 Molecular conservation and Differential mutation on ORF3a gene in Indian SARS-CoV2 genomes (edit) 10.1101/2020.05.14.096107
2020-04-30 A SARS-CoV-2 protein interaction map reveals targets for drug repurposing (edit) 10.1038/S41586-020-2286-9
This table is truncated. See the full table at sparql/litSARSCoV2Genes.rq

SARS-CoV-2タンパク質について

そしてウイルスタンパク質について

SPARQL sparql/litSARSCoV2Proteins.rq (実行, 編集)

SELECT (MAX(?dates) as ?date) ?work ?workLabel ?doi WHERE {
  ?protein wdt:P703 wd:Q82069695 ; wdt:P31 wd:Q8054 .
  ?work wdt:P921 ?protein .
  OPTIONAL { ?work wdt:P577 ?dates . }
  OPTIONAL { ?work wdt:P356 ?doi . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
} GROUP BY ?work ?workLabel ?doi ORDER BY DESC(?date)

結果は現在、以下の通りです。

date work doi
2022-12-01 ABO blood group is involved in the quality of the specific immune response anti-SARS-CoV-2 (edit) 10.1080/21505594.2021.2019959
2022-12-01 Computational investigation of potent inhibitors against SARS-CoV-2 2′-O-methyltransferase (nsp16): Structure-based pharmacophore modeling, molecular docking, molecular dynamics simulations and binding free energy calculations (edit) 10.1016/J.JMGM.2022.108306
2022-09-01 Frequent occurrence of mutations in nsp3 and nsp4 of SARS-CoV-2, presumably caused by the inhaled asthma drug ciclesonide (edit) 10.1093/PNASNEXUS/PGAC197
2022-08-18 In silico identification of novel SARS-CoV-2 main protease and non-structural protein 13 (nsp13) inhibitors through consensus docking and free binding energy calculations. (edit) 10.2174/1386207325666220818141112
2022-05-27 The mechanisms of catalysis and ligand binding for the SARS-CoV-2 NSP3 macrodomain from neutron and x-ray diffraction at room temperature (edit) 10.1126/SCIADV.ABO5083
2022-05-26 Parsing the role of NSP1 in SARS-CoV-2 infection (edit)
2022-05-20 Refolding of lid subdomain of SARS-CoV-2 nsp14 upon nsp10 interaction releases exonuclease activity (edit) 10.1016/J.STR.2022.04.014
2022-05-12 The role of NSP6 in the biogenesis of the SARS-CoV-2 replication organelle (edit) 10.1038/S41586-022-04835-6
This table is truncated. See the full table at sparql/litSARSCoV2Proteins.rq

コロナウイルスについて

2章で概説した通り、SARS-Cov-2はヒトに感染するコロナウイルスの一つです。

SPARQL sparql/litCoronaviruses.rq (実行, 編集)

SELECT (MAX(?dates) as ?date) ?work ?workLabel ?doi WHERE {
  ?work wdt:P921 wd:Q57751738 .
  OPTIONAL { ?work wdt:P577 ?dates . }
  OPTIONAL { ?work wdt:P356 ?doi . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
} GROUP BY ?work ?workLabel ?doi ORDER BY DESC(?date)

次の10件を取得できます。

date work doi
2022-08-05 A history of coronaviruses (edit) 10.15347/WJM/2022.005
2021-04-26 Fundamental evolution of all Orthocoronavirinae including three deadly lineages descendent from Chiroptera‐hosted coronaviruses: SARS‐CoV, MERS‐CoV and SARS‐CoV‐2 (edit) 10.1111/CLA.12454
2021-03-19 Major coronavirus variant found in pets for first time (edit) 10.1126/SCIENCE.ABI6152
2020-11-23 No Evidence of Coronaviruses or Other Potentially Zoonotic Viruses in Sunda pangolins (Manis javanica) Entering the Wildlife Trade via Malaysia (edit) 10.1007/S10393-020-01503-X
2020-09-08 Polyphenols vs. Coronaviruses: How Far Has Research Moved Forward? (edit) 10.3390/MOLECULES25184103
2020-09-01 A Guide to COVID-19: a global pandemic caused by the novel coronavirus SARS-CoV-2 (edit) 10.1111/FEBS.15375
2020-09-01 Wild birds as reservoirs for diverse and abundant gamma- and deltacoronaviruses (edit) 10.1093/FEMSRE/FUAA026
2020-08-27 Characterization of accessory genes in coronavirus genomes (edit) 10.1186/S12985-020-01402-1
This table is truncated. See the full table at sparql/litCoronaviruses.rq

ヒトのコロナウイルスについて

Wikidataには、7つのヒトコロナウイルスに関する記事が6千件以上あります。次のクエリは検索速度向上のために少し複雑になっています。また、得られる記事のリストが非常に長く、このページには表示しきれません。結果を見たい場合は、 litHumanCoronaviruses.rqファイルとある部分の下をクリックしてください。

SPARQL sparql/litHumanCoronaviruses.rq (実行, 編集)

SELECT ?date ?work ?workLabel ?virus ?virusLabel ?doi ?pubmed WITH {
  SELECT (MAX(?dates) as ?date) ?work ?doi ?virus WHERE {
    VALUES ?virus {
      wd:Q82069695 # SARS-CoV-2
      wd:Q16983360 # HKU1
      wd:Q16991954 # OC43
      wd:Q8351095  # NL63 
      wd:Q16983356 # 229E 
      wd:Q4902157  # MERS-CoV
      wd:Q278567   # SARS-CoV
    }
    ?work wdt:P577 ?dates ;
          wdt:P921 ?virus .
  } GROUP BY ?work ?doi ?virus
    ORDER BY DESC(?date)
    LIMIT 5000
} AS %ARTICLES WHERE {
  INCLUDE %ARTICLES
  OPTIONAL { ?work wdt:P356 ?doi . }
  OPTIONAL { ?work wdt:P698 ?pubmed . }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
}
ORDER BY DESC(?date) ?doi ?pubmed ?virus

さらに、個々のウイルスに関する記事の数は非常にまちまちであり、このクエリでそれを可視化できます。

SPARQL sparql/litHumanCoronavirusesCounts.rq (実行, 編集)

SELECT ?virus ?virusLabel ?count WITH {
  SELECT ?virus (COUNT(DISTINCT ?work) AS ?count) WHERE {
    VALUES ?virus {
      wd:Q82069695 # SARS-CoV-2
      wd:Q16983360 # HKU1
      wd:Q16991954 # OC43
      wd:Q8351095  # NL63 
      wd:Q16983356 # 229E 
      wd:Q4902157  # MERS-CoV
      wd:Q278567   # SARS-CoV
    }
    ?work wdt:P921 ?virus .
  } GROUP BY ?virus
} AS %ARTICLES WHERE {
  INCLUDE %ARTICLES
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
}
ORDER BY DESC(?count)

以下の結果が得られます。

virus count
SARSコロナウイルス2 (edit) 24131
SARS関連コロナウイルス (edit) 2487
MERSコロナウイルス (edit) 1051
ベータコロナウイルス1 (edit) 114
ヒトコロナウイルス229E (edit) 107
ヒトコロナウイルスNL63 (edit) 94
ヒトコロナウイルスHKU1 (edit) 22

そしてそれらの遺伝子です

SPARQL sparql/litHumanCoronavirusesGeneCounts.rq (実行, 編集)

SELECT ?virus ?virusLabel ?gene ?geneLabel ?count WITH {
  SELECT ?virus ?gene (COUNT(DISTINCT ?work) AS ?count) WHERE {
    VALUES ?virus {
      wd:Q82069695 # SARS-CoV-2
      wd:Q16983360 # HKU1
      wd:Q16991954 # OC43
      wd:Q8351095  # NL63 
      wd:Q16983356 # 229E 
      wd:Q4902157  # MERS-CoV
      wd:Q278567   # SARS-CoV
    }
    ?gene wdt:P703 ?virus ; wdt:P31 wd:Q7187 .
    ?work wdt:P921 ?gene .
  } GROUP BY ?virus ?gene
} AS %ARTICLES WHERE {
  INCLUDE %ARTICLES
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
}
ORDER BY DESC(?count)

以下の結果が得られます。

virus gene count
ヒトコロナウイルスNL63 (edit) membrane protein (edit) 7
SARSコロナウイルス2 (edit) ORF8 protein (edit) 6
SARSコロナウイルス2 (edit) ORF7b (edit) 3
ヒトコロナウイルスNL63 (edit) nucleocapsid protein (edit) 3
ヒトコロナウイルスNL63 (edit) envelope protein (edit) 3
ヒトコロナウイルスNL63 (edit) spike protein (edit) 3
ベータコロナウイルス1 (edit) spike surface glycoprotein (edit) 2
SARSコロナウイルス2 (edit) nucleocapsid phosphoprotein (edit) 2
SARSコロナウイルス2 (edit) ORF3a protein-encoding gene (edit) 2
SARSコロナウイルス2 (edit) 表面糖タンパク質 (edit) 2
ヒトコロナウイルスNL63 (edit) ORF1a polyprotein;ORF1ab polyprotein (edit) 2
ヒトコロナウイルスNL63 (edit) protein 3 (edit) 2
ヒトコロナウイルス229E (edit) nucleocapsid protein (edit) 2
ヒトコロナウイルス229E (edit) surface glycoprotein (edit) 2
ベータコロナウイルス1 (edit) membrane protein (edit) 1
ベータコロナウイルス1 (edit) I protein;nucleocapsid protein (edit) 1
ベータコロナウイルス1 (edit) ns2 (edit) 1
SARSコロナウイルス2 (edit) ORF7a protein (edit) 1
SARSコロナウイルス2 (edit) membrane glycoprotein (edit) 1
SARSコロナウイルス2 (edit) envelope protein (edit) 1
SARSコロナウイルス2 (edit) ORF1a polyprotein;ORF1ab polyprotein (edit) 1
SARS関連コロナウイルス (edit) matrix protein (edit) 1
ヒトコロナウイルス229E (edit) envelope protein (edit) 1
ヒトコロナウイルス229E (edit) membrane protein (edit) 1
ヒトコロナウイルス229E (edit) 4b protein (edit) 1
ヒトコロナウイルス229E (edit) 4a protein (edit) 1
ヒトコロナウイルスHKU1 (edit) membrane glycoprotein (edit) 1
ヒトコロナウイルスHKU1 (edit) hemagglutinin-esterase glycoprotein (edit) 1
ヒトコロナウイルスHKU1 (edit) ORF1a polyprotein;ORF1ab polyprotein (edit) 1
ヒトコロナウイルスHKU1 (edit) nucleocapsid phosphoprotein (edit) 1
ヒトコロナウイルスHKU1 (edit) envelope protein (edit) 1
ヒトコロナウイルスHKU1 (edit) spike glycoprotein (edit) 1

それから、他のタンパク質です

SPARQL sparql/litHumanCoronavirusesProteinCounts.rq (実行, 編集)

SELECT ?virus ?virusLabel ?protein ?proteinLabel ?count WITH {
  SELECT ?virus ?protein (COUNT(DISTINCT ?work) AS ?count) WHERE {
    VALUES ?virus {
      wd:Q82069695 # SARS-CoV-2
      wd:Q16983360 # HKU1
      wd:Q16991954 # OC43
      wd:Q8351095  # NL63 
      wd:Q16983356 # 229E 
      wd:Q4902157  # MERS-CoV
      wd:Q278567   # SARS-CoV
    }
    ?protein wdt:P31 wd:Q8054 .
    { ?protein wdt:P703 ?virus }
    UNION
    { ?protein wdt:P702 | ^wdt:P688 ?gene . ?gene wdt:P703 ?virus }
    ?work wdt:P921 ?protein .
  } GROUP BY ?virus ?protein
} AS %ARTICLES WHERE {
  INCLUDE %ARTICLES
  SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
}
ORDER BY DESC(?count) ?virus ?protein

そして、以下のクエリでそれらを取得します。

virus protein count
SARSコロナウイルス2 (edit) spike glycoprotein [SARS-CoV-2] (edit) 415
SARSコロナウイルス2 (edit) nucleocapsid protein [SARS-CoV-2] (edit) 108
SARS関連コロナウイルス (edit) spike glycoprotein [SARS-Cov] (edit) 98
SARSコロナウイルス2 (edit) Papain-like proteinase [SARS-CoV-2] (edit) 74
SARS関連コロナウイルス (edit) nucleoprotein [SARS-Cov] (edit) 70
SARS関連コロナウイルス (edit) 3C-like proteinase [SARS-Cov] (edit) 66
SARSコロナウイルス2 (edit) non-structural protein 5 [SARS-CoV-2] (edit) 59
SARSコロナウイルス2 (edit) Non-structural protein 10 [SARS CoV-2] (edit) 57
SARSコロナウイルス2 (edit) RNA-directed RNA polymerase [SARS-CoV-2] (edit) 57
SARSコロナウイルス2 (edit) Host translation inhibitor nsp1 [SARS-CoV-2] (edit) 51
SARS関連コロナウイルス (edit) papain-like proteinase [SARS-Cov] (edit) 46
SARSコロナウイルス2 (edit) non-structural protein 16 [SARS-CoV-2] (edit) 45
SARSコロナウイルス2 (edit) Non-structural protein 14 [SARS-CoV-2] (edit) 43
SARS関連コロナウイルス (edit) Protein 3a [SARS-Cov] (edit) 41
SARSコロナウイルス2 (edit) Helicase [SARS-CoV-2] (edit) 41
SARS関連コロナウイルス (edit) Envelope small membrane protein [SARS-Cov] (edit) 38
SARSコロナウイルス2 (edit) envelope protein [SARS-CoV-2] (edit) 34
SARSコロナウイルス2 (edit) ORF8 protein [SARS-CoV-2] (edit) 31
SARSコロナウイルス2 (edit) Viroporin 3a [SARS-CoV-2] (edit) 30
SARSコロナウイルス2 (edit) non-structural protein 15 [SARS-CoV-2] (edit) 28
SARSコロナウイルス2 (edit) Non-structural protein 7 [SARS-CoV-2] (edit) 26
SARS関連コロナウイルス (edit) Membrane protein [SARS-Cov] (edit) 25
SARSコロナウイルス2 (edit) membrane protein [SARS-CoV-2] (edit) 25
SARSコロナウイルス2 (edit) Non-structural protein nsp8 [SARS-CoV-2] (edit) 25
SARS関連コロナウイルス (edit) Non-structural protein NS6 [SARS-Cov] (edit) 20
SARSコロナウイルス2 (edit) ORF6 protein [SARS-CoV-2] (edit) 20
SARSコロナウイルス2 (edit) Protein 7a [SARS-CoV-2] (edit) 19
SARS関連コロナウイルス (edit) host translation inhibitor nsp1 [SARS-Cov] (edit) 17
SARSコロナウイルス2 (edit) Non-structural protein 9 [SARS-CoV-2] (edit) 17
SARS関連コロナウイルス (edit) Protein 7a [SARS-Cov] (edit) 15
SARSコロナウイルス2 (edit) Protein ORF9b [SARS-CoV-2] (edit) 15
SARSコロナウイルス2 (edit) Non-structural protein 2 [SARS CoV-2] (edit) 14
SARSコロナウイルス2 (edit) non-structural protein 6 [SARS-CoV-2] (edit) 12
SARS関連コロナウイルス (edit) Non-structural protein 3b [SARS-Cov] (edit) 10
SARS関連コロナウイルス (edit) 2'-O-methyltransferase [SARS-Cov] (edit) 10
SARS関連コロナウイルス (edit) Guanine-N7 methyltransferase [SARS-Cov] (edit) 10
SARS関連コロナウイルス (edit) protein non-structural 8a [SARS-Cov] (edit) 10
MERSコロナウイルス (edit) spike glycoprotein (edit) 10
SARS関連コロナウイルス (edit) helicase [SARS-Cov] (edit) 9
SARSコロナウイルス2 (edit) Non-structural protein 4 [SARS-CoV-2] (edit) 9
SARS関連コロナウイルス (edit) Protein 9b [SARS-Cov] (edit) 8
SARS関連コロナウイルス (edit) uridylate-specific endoribonuclease [SARS-Cov] (edit) 8
SARS関連コロナウイルス (edit) non-structural protein 10 [SARS-Cov] (edit) 8
SARS関連コロナウイルス (edit) protein non-structural 8b [SARS-Cov] (edit) 8
SARSコロナウイルス2 (edit) ORF10 protein [SARS-CoV-2] (edit) 8
SARS関連コロナウイルス (edit) replicase polyprotein 1ab [SARS-Cov] (edit) 7
SARS関連コロナウイルス (edit) RNA-directed RNA polymerase [SARS-Cov] (edit) 7
SARSコロナウイルス2 (edit) ORF3b protein [SARS-CoV-2] (edit) 7
SARSコロナウイルス2 (edit) Protein non-structural 7b [SARS-CoV-2] (edit) 7
SARS関連コロナウイルス (edit) Protein non-structural 7b [SARS-Cov] (edit) 6
SARS関連コロナウイルス (edit) non-structural protein 7 [SARS-Cov] (edit) 6
SARS関連コロナウイルス (edit) non-structural protein 8 [SARS-Cov] (edit) 6
ベータコロナウイルス1 (edit) nucleocapsid protein (edit) 5
SARS関連コロナウイルス (edit) non-structural protein 9 [SARS-Cov] (edit) 5
SARS関連コロナウイルス (edit) spike protein S2 [SARS-Cov] (edit) 5
SARS関連コロナウイルス (edit) non-structural protein 4 [SARS-Cov] (edit) 5
ヒトコロナウイルスNL63 (edit) Spike glycoprotein [NL63] (edit) 5
ベータコロナウイルス1 (edit) spike surface glycoprotein (edit) 4
ヒトコロナウイルスHKU1 (edit) Spike glycoprotein (edit) 3
SARS関連コロナウイルス (edit) non-structural protein 6 [SARS-Cov] (edit) 3
SARS関連コロナウイルス (edit) non-structural protein 2 [SARS-Cov] (edit) 3
MERSコロナウイルス (edit) nucleoprotein (edit) 3
SARSコロナウイルス2 (edit) orf1ab polyprotein [SARS-Cov 2] (edit) 3
ヒトコロナウイルス229E (edit) Non-structural protein 4b (edit) 2
ヒトコロナウイルス229E (edit) Spike glycoprotein (edit) 2
ヒトコロナウイルスHKU1 (edit) Replicase polyprotein 1ab (edit) 2
ベータコロナウイルス1 (edit) ns12.9 (edit) 2
ベータコロナウイルス1 (edit) hemagglutinin-esterase (edit) 2
SARSコロナウイルス2 (edit) Non-structural protein 11 [SARS CoV-2] (edit) 2
SARSコロナウイルス2 (edit) ORF9c protein [SARS CoV-2] (edit) 2
ヒトコロナウイルスNL63 (edit) Nucleoprotein (edit) 2
ヒトコロナウイルス229E (edit) Non-structural protein 4a (edit) 1
ヒトコロナウイルス229E (edit) Nucleoprotein (edit) 1
ヒトコロナウイルス229E (edit) Replicase polyprotein 1ab (edit) 1
ヒトコロナウイルスHKU1 (edit) Spike glycoprotein (edit) 1
ヒトコロナウイルスHKU1 (edit) Membrane protein (edit) 1
ベータコロナウイルス1 (edit) ns2 (edit) 1
ベータコロナウイルス1 (edit) membrane protein (edit) 1
SARS関連コロナウイルス (edit) Replicase polyprotein 1a (edit) 1
MERSコロナウイルス (edit) NS4B protein (edit) 1
SARSコロナウイルス2 (edit) putative protein ORF3c (edit) 1
ヒトコロナウイルスNL63 (edit) Membrane protein (edit) 1

参考文献

  1. Rasberry L, Willighagen E, Nielsen FÅ, Mietchen D. Robustifying Scholia: paving the way for knowledge discovery and research assessment through Wikidata. RIO Journal [Internet]. 2019 May 2;5. Available from: https://riojournal.com/article/35820/ doi:10.3897/RIO.5.E35820 (Scholia)