Estas buscas retornoma os últimos 10 artigos sobre uma série de temas.Não é um substituto para o Scholia [1], que tem uma visão muito mais rica da literatura sobre el tema. Cada seção inclui uma ligação à página do Scholia para esse tema. As consultas feitas aqui são básicas e usam somente a propriedade “tópico principal da obra”.
SARS-CoV-2 es el nombre del virus.
SPARQL sparql/litSARSCoV2.rq (run, edit)
SELECT (MAX(?dates) as ?date) ?work ?workLabel ?doi WHERE {
?work wdt:P921 wd:Q82069695 .
OPTIONAL { ?work wdt:P577 ?dates . }
OPTIONAL { ?work wdt:P356 ?doi . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} GROUP BY ?work ?workLabel ?doi ORDER BY DESC(?date) ?work
Isto te fornece 10 documentos:
Também podemos consultar artigos sobre os genes relacionados à COVID-19:
SPARQL sparql/litSARSCoV2Genes.rq (run, edit)
SELECT (MAX(?dates) as ?date) ?work ?workLabel ?doi WHERE {
?gene wdt:P703 wd:Q82069695 ; wdt:P31 wd:Q7187 .
?work wdt:P921 ?gene .
OPTIONAL { ?work wdt:P577 ?dates . }
OPTIONAL { ?work wdt:P356 ?doi . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} GROUP BY ?work ?workLabel ?doi ORDER BY DESC(?date)
Que atualmente dá:
E sobre as proteínas do virus:
SPARQL sparql/litSARSCoV2Proteins.rq (run, edit)
SELECT (MAX(?dates) as ?date) ?work ?workLabel ?doi WHERE {
?protein wdt:P703 wd:Q82069695 ; wdt:P31 wd:Q8054 .
?work wdt:P921 ?protein .
OPTIONAL { ?work wdt:P577 ?dates . }
OPTIONAL { ?work wdt:P356 ?doi . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} GROUP BY ?work ?workLabel ?doi ORDER BY DESC(?date)
Que atualmente dá:
Como descrevemos no capítulo ??,, o SARS-Cov-2 é somente um dos coronavirus que podem infectar seres humanos.
SPARQL sparql/litCoronaviruses.rq (run, edit)
SELECT (MAX(?dates) as ?date) ?work ?workLabel ?doi WHERE {
?work wdt:P921 wd:Q57751738 .
OPTIONAL { ?work wdt:P577 ?dates . }
OPTIONAL { ?work wdt:P356 ?doi . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} GROUP BY ?work ?workLabel ?doi ORDER BY DESC(?date)
A busca te dá estes 10 documentos:
Há mais de 6000 artigos sobre os sete coronavírus humanos em Wikidata. Por isso, a consulta está ajustada para desempenho e, por isso, tem uma estrutura mais complexa. Além disso, a lista é enorme e não cabe na página. Para ver o resultado, clique na continuação no nome do arquivo litHumanCoronaviruses.rq:
SPARQL sparql/litHumanCoronaviruses.rq (run, edit)
SELECT ?date ?work ?workLabel ?virus ?virusLabel ?doi ?pubmed WITH {
SELECT (MAX(?dates) as ?date) ?work ?doi ?virus WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?work wdt:P577 ?dates ;
wdt:P921 ?virus .
} GROUP BY ?work ?doi ?virus
ORDER BY DESC(?date)
LIMIT 5000
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
OPTIONAL { ?work wdt:P356 ?doi . }
OPTIONAL { ?work wdt:P698 ?pubmed . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
ORDER BY DESC(?date) ?doi ?pubmed ?virus
Além disso, o número de artigos para cada vírus varia notavelmnte, o que pode ser visualizado com essa consulta:
SPARQL sparql/litHumanCoronavirusesCounts.rq (run, edit)
SELECT ?virus ?virusLabel ?count WITH {
SELECT ?virus (COUNT(DISTINCT ?work) AS ?count) WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?work wdt:P921 ?virus .
} GROUP BY ?virus
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
ORDER BY DESC(?count)
O que nos diz:
| virus | count |
| coronavírus da síndrome respiratória aguda grave 2 (edit) | 24131 |
| SARS-CoV (edit) | 2487 |
| coronavírus da síndrome respiratória do Oriente Médio (edit) | 1051 |
| Coronavírus humano OC43 (edit) | 114 |
| Coronavírus humano 229E (edit) | 107 |
| Coronavírus humano NL63 (edit) | 94 |
| Coronavírus humano HKU1 (edit) | 22 |
SPARQL sparql/litHumanCoronavirusesGeneCounts.rq (run, edit)
SELECT ?virus ?virusLabel ?gene ?geneLabel ?count WITH {
SELECT ?virus ?gene (COUNT(DISTINCT ?work) AS ?count) WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?gene wdt:P703 ?virus ; wdt:P31 wd:Q7187 .
?work wdt:P921 ?gene .
} GROUP BY ?virus ?gene
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
ORDER BY DESC(?count)
O que nos mostra:
SPARQL sparql/litHumanCoronavirusesProteinCounts.rq (run, edit)
SELECT ?virus ?virusLabel ?protein ?proteinLabel ?count WITH {
SELECT ?virus ?protein (COUNT(DISTINCT ?work) AS ?count) WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?protein wdt:P31 wd:Q8054 .
{ ?protein wdt:P703 ?virus }
UNION
{ ?protein wdt:P702 | ^wdt:P688 ?gene . ?gene wdt:P703 ?virus }
?work wdt:P921 ?protein .
} GROUP BY ?virus ?protein
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
ORDER BY DESC(?count) ?virus ?protein
Onde encontramos: