This chapter gives an over of the genes and proteins of the other SARS-related and other human coronaviruses.
All genes we get with:
SPARQL sparql/virusGenesSARSr.rq (run, edit)
SELECT ?virus ?virusLabel ?gene ?geneLabel ?ncbigene WHERE {
VALUES ?virus {
wd:Q16000326 # SL-CoV-WIV1
wd:Q88162038 # Bat SARS coronavirus Rp1
wd:Q85939995 # SHC014-CoV
wd:Q82069695 # SARS-CoV-2
wd:Q34967815 # SARS coronavirus
wd:Q85438966 # severe acute respiratory syndrome coronavirus
wd:Q278567 # SARSr-CoV / SARS-CoV
}
?gene wdt:P703 ?virus ; wdt:P31 wd:Q7187 .
OPTIONAL { ?gene wdt:P351 ?ncbigene }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
}
Which returns:
And all proteins we get with:
SPARQL sparql/virusProteinsSARSr.rq (run, edit)
SELECT ?virus ?virusLabel ?protein ?proteinLabel ?refseq ?uniprot WHERE {
VALUES ?virus {
wd:Q16000326 # SL-CoV-WIV1
wd:Q88162038 # Bat SARS coronavirus Rp1
wd:Q85939995 # SHC014-CoV
wd:Q82069695 # SARS-CoV-2
wd:Q34967815 # SARS coronavirus
wd:Q85438966 # severe acute respiratory syndrome coronavirus
wd:Q278567 # SARSr-CoV / SARS-CoV
}
?protein wdt:P703 ?virus ; wdt:P31 wd:Q8054 .
OPTIONAL { ?protein wdt:P637 ?refseq }
OPTIONAL { ?protein wdt:P352 ?uniprot }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
} ORDER BY ASC(?virus) ASC(?protein)
Which returns:
Much like that above query, we can also ask for all genes and proteins. This is done with the following queries.
All genes we get with:
SPARQL sparql/virusGenesAll.rq (run, edit)
SELECT ?virus ?virusLabel ?gene ?geneLabel ?ncbigene WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?gene wdt:P703 ?virus ; wdt:P31 wd:Q7187 .
OPTIONAL { ?gene wdt:P351 ?ncbigene }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
} ORDER BY ?virus ?ncbigene ?gene
Which returns:
And all proteins we get with:
SPARQL sparql/virusProteinsAll.rq (run, edit)
SELECT ?virus ?virusLabel ?protein ?proteinLabel ?refseq ?uniprot WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?protein wdt:P703 ?virus ; wdt:P31 wd:Q8054 .
OPTIONAL { ?protein wdt:P637 ?refseq }
OPTIONAL { ?protein wdt:P352 ?uniprot }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
} ORDER BY ?virus
Which returns: