Talvez a primeira pergunta sobre esse tema possa ser: quais genomas foram já analisados para o SARS-CoV-2:
SPARQL sparql/genomes.rq (run, edit)
SELECT ?genome WHERE {
wd:Q82069695 wdt:P527/wdt:P6800 ?genome .
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
Que lista as URLs de genoma:
| genome |
| https://gisaid.org/CoV2020 |
| https://www.ncbi.nlm.nih.gov/assembly/GCF_009858895.2 |
| https://www.ncbi.nlm.nih.gov/genome/86693 |
| https://www.ncbi.nlm.nih.gov/nuccore/1798174254 |
O RNA do SARS-CoV-2 já foi sequenciado. Dessa forma, os quadros abertos de leitura (ORFs) são conhecidos e identificados. Podemos consultar a informação sobre genes na Wikidata com essa busca:
SPARQL sparql/virusGenes.rq (run, edit)
SELECT ?gene ?geneLabel ?ncbigene WHERE {
?gene wdt:P703 wd:Q82069695 ; wdt:P31 wd:Q7187 .
OPTIONAL { ?gene wdt:P351 ?ncbigene }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
O que nos dá esses genes:
Alternativamente, podemos estar interessados nas proteínas dos coronavirus. Podemos obtê-las com essa busca:
SPARQL sparql/virusProteins.rq (run, edit)
SELECT ?protein ?proteinLabel ?short ?refseq ?uniprot ?guideToPharma WHERE {
?protein wdt:P703 wd:Q82069695 ; wdt:P31 wd:Q8054 .
OPTIONAL { ?protein wdt:P637 ?refseq }
OPTIONAL { ?protein wdt:P352 ?uniprot }
OPTIONAL { ?protein wdt:P5458 ?guideToPharma }
OPTIONAL { ?protein wdt:P1813 ?short }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
} ORDER BY ASC(?protein) ASC(?uniprot)
O que nos dá essas proteínas:
Graças ao trabalho realizado por uma equipe no BioHackathon online em April 2020, as estruturas macromoleculares do Complex Portal [1] foram inseridas no Wikidata:
SPARQL sparql/complexes.rq (run, edit)
SELECT ?cpx ?complex ?complexLabel WHERE {
?complex wdt:P7718 ?cpx ;
wdt:P703 wd:Q82069695
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
Lista destes complexos:
Para as proteínas, podemos consultar as estruturas do PDB [2]:
SPARQL sparql/virusProteinsPDB.rq (run, edit)
SELECT ?protein ?proteinLabel ?refseq ?uniprot ?pdb WHERE {
?protein wdt:P703 wd:Q82069695 ; wdt:P31 wd:Q8054 .
?protein wdt:P638 ?pdb .
OPTIONAL { ?protein wdt:P637 ?refseq }
OPTIONAL { ?protein wdt:P352 ?uniprot }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
O que nos dá:
Assim comoa a consulta anterior, também podemos buscar todos os genes e proteínas de todos os vírus relacionados com o SARS. Isso se faz com as seguintes consultas:
Todos os genes que obtemos com:
SPARQL sparql/virusGenesSARSr.rq (run, edit)
SELECT ?virus ?virusLabel ?gene ?geneLabel ?ncbigene WHERE {
VALUES ?virus {
wd:Q16000326 # SL-CoV-WIV1
wd:Q88162038 # Bat SARS coronavirus Rp1
wd:Q85939995 # SHC014-CoV
wd:Q82069695 # SARS-CoV-2
wd:Q34967815 # SARS coronavirus
wd:Q85438966 # severe acute respiratory syndrome coronavirus
wd:Q278567 # SARSr-CoV / SARS-CoV
}
?gene wdt:P703 ?virus ; wdt:P31 wd:Q7187 .
OPTIONAL { ?gene wdt:P351 ?ncbigene }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
Que devolve:
E todas as proteínas que obtemos com:
SPARQL sparql/virusProteinsSARSr.rq (run, edit)
SELECT ?virus ?virusLabel ?protein ?proteinLabel ?refseq ?uniprot WHERE {
VALUES ?virus {
wd:Q16000326 # SL-CoV-WIV1
wd:Q88162038 # Bat SARS coronavirus Rp1
wd:Q85939995 # SHC014-CoV
wd:Q82069695 # SARS-CoV-2
wd:Q34967815 # SARS coronavirus
wd:Q85438966 # severe acute respiratory syndrome coronavirus
wd:Q278567 # SARSr-CoV / SARS-CoV
}
?protein wdt:P703 ?virus ; wdt:P31 wd:Q8054 .
OPTIONAL { ?protein wdt:P637 ?refseq }
OPTIONAL { ?protein wdt:P352 ?uniprot }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY ASC(?virus) ASC(?protein)
Que devolve:
Como na busca anterior, também podemos pedir por todos os genes e proteínas. Isso se faz com as seguintes buscas:
Todos os genes que obtemos são:
SPARQL sparql/virusGenesAll.rq (run, edit)
SELECT ?virus ?virusLabel ?gene ?geneLabel ?ncbigene WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?gene wdt:P703 ?virus ; wdt:P31 wd:Q7187 .
OPTIONAL { ?gene wdt:P351 ?ncbigene }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY ?virus ?ncbigene ?gene
Que devolve:
E todas as proteínas que obtemos com:
SPARQL sparql/virusProteinsAll.rq (run, edit)
SELECT ?virus ?virusLabel ?protein ?proteinLabel ?refseq ?uniprot WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?protein wdt:P703 ?virus ; wdt:P31 wd:Q8054 .
OPTIONAL { ?protein wdt:P637 ?refseq }
OPTIONAL { ?protein wdt:P352 ?uniprot }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY ?virus
Que retorna: