Quizás la primera pregunta debería ser: Qué genomas se han medido para el virus SARS-CoV-2:
SPARQL sparql/genomes.rq (ejecutar, editar)
SELECT ?genome WHERE {
wd:Q82069695 wdt:P527/wdt:P6800 ?genome .
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
Que enumera estas URL del genoma:
| genome |
| https://gisaid.org/CoV2020 |
| https://www.ncbi.nlm.nih.gov/assembly/GCF_009858895.2 |
| https://www.ncbi.nlm.nih.gov/genome/86693 |
| https://www.ncbi.nlm.nih.gov/nuccore/1798174254 |
El ARN del SARS-CoV-2 ha sido secuenciado. Por lo tanto, los marcos abiertos de lectura son conocidos e identificados. Podemos consultar la información del gen en Wikidata con esta consulta:
SPARQL sparql/virusGenes.rq (ejecutar, editar)
SELECT ?gene ?geneLabel ?ncbigene WHERE {
?gene wdt:P703 wd:Q82069695 ; wdt:P31 wd:Q7187 .
OPTIONAL { ?gene wdt:P351 ?ncbigene }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
Lo que nos da estos genes:
Alternativamente, podemos estar interesados en las proteínas de los coronavirus. Podemos obtener aquellos con esta consulta:
SPARQL sparql/virusProteins.rq (ejecutar, editar)
SELECT ?protein ?proteinLabel ?short ?refseq ?uniprot ?guideToPharma WHERE {
?protein wdt:P703 wd:Q82069695 ; wdt:P31 wd:Q8054 .
OPTIONAL { ?protein wdt:P637 ?refseq }
OPTIONAL { ?protein wdt:P352 ?uniprot }
OPTIONAL { ?protein wdt:P5458 ?guideToPharma }
OPTIONAL { ?protein wdt:P1813 ?short }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
} ORDER BY ASC(?protein) ASC(?uniprot)
Lo que nos da estas proteínas:
Gracias al trabajo realizado por un equipo en el BioHackathon en línea en April 2020, estructuras macromoleculares del Complex Portal [1] han estado entrando en Wikidata:
SPARQL sparql/complexes.rq (ejecutar, editar)
SELECT ?cpx ?complex ?complexLabel WHERE {
?complex wdt:P7718 ?cpx ;
wdt:P703 wd:Q82069695
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
Listado de estos complejos:
Para las proteínas, podemos consultar las estructuras PDB [2]:
SPARQL sparql/virusProteinsPDB.rq (ejecutar, editar)
SELECT ?protein ?proteinLabel ?refseq ?uniprot ?pdb WHERE {
?protein wdt:P703 wd:Q82069695 ; wdt:P31 wd:Q8054 .
?protein wdt:P638 ?pdb .
OPTIONAL { ?protein wdt:P637 ?refseq }
OPTIONAL { ?protein wdt:P352 ?uniprot }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
Lo que nos da:
Al igual que en la consulta anterior, también podemos solicitar todos los genes y proteínas de todos los virus relacionados con el SARS. Esto se hace con las siguientes consultas.
Todos los genes que obtenemos con:
SPARQL sparql/virusGenesSARSr.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?gene ?geneLabel ?ncbigene WHERE {
VALUES ?virus {
wd:Q16000326 # SL-CoV-WIV1
wd:Q88162038 # Bat SARS coronavirus Rp1
wd:Q85939995 # SHC014-CoV
wd:Q82069695 # SARS-CoV-2
wd:Q34967815 # SARS coronavirus
wd:Q85438966 # severe acute respiratory syndrome coronavirus
wd:Q278567 # SARSr-CoV / SARS-CoV
}
?gene wdt:P703 ?virus ; wdt:P31 wd:Q7187 .
OPTIONAL { ?gene wdt:P351 ?ncbigene }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
Que devuelve:
Y todas las proteínas que obtenemos con:
SPARQL sparql/virusProteinsSARSr.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?protein ?proteinLabel ?refseq ?uniprot WHERE {
VALUES ?virus {
wd:Q16000326 # SL-CoV-WIV1
wd:Q88162038 # Bat SARS coronavirus Rp1
wd:Q85939995 # SHC014-CoV
wd:Q82069695 # SARS-CoV-2
wd:Q34967815 # SARS coronavirus
wd:Q85438966 # severe acute respiratory syndrome coronavirus
wd:Q278567 # SARSr-CoV / SARS-CoV
}
?protein wdt:P703 ?virus ; wdt:P31 wd:Q8054 .
OPTIONAL { ?protein wdt:P637 ?refseq }
OPTIONAL { ?protein wdt:P352 ?uniprot }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} ORDER BY ASC(?virus) ASC(?protein)
Que devuelve:
Al igual que en la consulta anterior, también podemos pedir todos los genes y proteínas. Esto se hace con las siguientes consultas.
Todos los genes que obtenemos con:
SPARQL sparql/virusGenesAll.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?gene ?geneLabel ?ncbigene WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?gene wdt:P703 ?virus ; wdt:P31 wd:Q7187 .
OPTIONAL { ?gene wdt:P351 ?ncbigene }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} ORDER BY ?virus ?ncbigene ?gene
Que devuelve:
Y todas las proteínas que obtenemos con:
SPARQL sparql/virusProteinsAll.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?protein ?proteinLabel ?refseq ?uniprot WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?protein wdt:P703 ?virus ; wdt:P31 wd:Q8054 .
OPTIONAL { ?protein wdt:P637 ?refseq }
OPTIONAL { ?protein wdt:P352 ?uniprot }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} ORDER BY ?virus
Que devuelve: