Actualmente no existe una solución para el SARS-CoV-2.
Pero hay ideas sobre qué soluciones podrían ser. Una vacuna es una de ellas, pero su desarrollo lleva tiempo [1]. Pero también se habla de anticuerpos y reutilización de drogas. Todo esto es muy exploratorio en este momento. Los ensayos clínicos son importantes (consulte la sección Ensayos clínicos).
Este capítulo muestra una serie de consultas con información en Wikidata sobre clientes potenciales que las personas han propuesto que pueden conducir a una solución.
Los anticuerpos están ganando interés. La siguiente consulta enumera artículos sobre los coronavirus humanos y también anotados con el término ‘anticuerpo’:
SPARQL sparql/antibodies.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?work ?workLabel WITH {
SELECT ?virus ?work WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?work wdt:P921 ?virus ;
wdt:P921 wd:Q79460 .
}
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
ORDER BY ?virusLabel ?virus ?workLabel ?work
La lista se está haciendo larga, así que primero vamos a mostrar la cantidad de artículos sobre anticuerpos para cada virus:
| virus | count |
| SARS coronavirus (edit) | 48 |
| MERS-CoV (edit) | 16 |
| SARS-CoV-2 (edit) | 13 |
| Human coronavirus 229E (edit) | 2 |
| Human coronavirus OC43 (edit) | 1 |
Se debe enfatizar que los anticuerpos son específicos para cada proteína y cada coronavirus tiene proteínas diferentes, y esta lista es solo para incluir en la literatura relevante para leer, no para sacar conclusiones de:
La sección ?? ya incluía una descripción general de los ensayos clínicos. Este da una idea de los síntomas que preocupan a las personas. También proporciona información sobre qué medicamentos se estudian para la reutilización. Algunos de estos han recibido mucha atención, otros menos. Ellos se ven asi:
La siguiente consulta enumera el número de ensayos clínicos por intervención:
SPARQL sparql/clinicalTrialsByIntervention.rq (ejecutar, editar)
SELECT ?intervention ?interventionLabel (COUNT(?trial) AS ?trials) WHERE {
VALUES ?topic {
wd:Q84263196 wd:Q82069695
}
?trial wdt:P31 wd:Q30612 ;
wdt:P921 ?topic ;
wdt:P4844 ?intervention .
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} GROUP BY ?intervention ?interventionLabel
ORDER BY DESC(?trials) ASC(?intervention)
Esto da:
| intervention | trials |
| hidroxicloroquina (edit) | 43 |
| Cloroquina (edit) | 15 |
| Lopinavir (edit) | 15 |
| Ritonavir (edit) | 15 |
| Chloroquine diphosphate bearing dextran nanoparticles augmented drug delivery and overwhelmed drug resistance in Plasmodium falciparum parasites (edit) | 12 |
| tocilizumab (edit) | 6 |
| interferón (edit) | 4 |
| óxido nítrico (edit) | 4 |
| agente antiviral (edit) | 4 |
| losartán, losartano (edit) | 4 |
| paracetamol (edit) | 4 |
| Prednisolona (edit) | 3 |
| azitromicina (edit) | 3 |
| This table is truncated. See the full table at sparql/clinicalTrialsByIntervention.rq | |
Es importante destacar que esta lista solo da una idea de qué intervención ha recibido más atención que otras. Y es esencial darse cuenta de que la atención no es una medida de éxito.