Atualmente não existe uma solução para o SARS-CoV-2.
Há, contudo, ideias sobre como as soluções poderiam ser. Uma vacina é uma possível solução, mas seu desenvolvimento leva tempo [1]. Também se fala em uso de soros (anticorpos) e reaproveitamento de drogas conhecidas. Tudo isso é muito exploratório nesse momento. Os ensaios clínicos são importantíssimos (consulte a seção Ensaios clínicos).
Este capítulo mostra uma série de buscas de informações no Wikidata sobre agentes relacionados à busca de soluções para a COVID-19.
A busca por anticorpos eficazes tem ganhado bastante tração. A consulta a seguir enumera artigos sobre os coronavírus humanos também anotados com o termo ‘anticorpo’:
SPARQL sparql/antibodies.rq (run, edit)
SELECT ?virus ?virusLabel ?work ?workLabel WITH {
SELECT ?virus ?work WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?work wdt:P921 ?virus ;
wdt:P921 wd:Q79460 .
}
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
ORDER BY ?virusLabel ?virus ?workLabel ?work
A lista está crescendo bastante, então vamos mostrar somente a quantidade de artigos sobre anticorpos para cada vírus:
Deve-se enfatizar que os anticorpos são específicos para cada proteína e cada coronavírus tem proteínas diferentes. Essa lista, então, é apenas um agregados de artigos relevantes, mas não para se tirar conclusões imediatas.
A seção 8.3 inclui uma descrição geral dos ensaios clínicos. Esta aqui dá uma ideia dos sintomas que preocupam às pessoas. Também traz informações sobre quais medicamentos se estudam para reuso. Alguns destes tem recebido mais atenção, outros menos.
A busca a seguir conta o número de ensaios clínicos no Wikidata por intervenção de pesquisa:
SPARQL sparql/clinicalTrialsByIntervention.rq (run, edit)
SELECT ?intervention ?interventionLabel (COUNT(?trial) AS ?trials) WHERE {
VALUES ?topic {
wd:Q84263196 wd:Q82069695
}
?trial wdt:P31 wd:Q30612 ;
wdt:P921 ?topic ;
wdt:P4844 ?intervention .
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} GROUP BY ?intervention ?interventionLabel
ORDER BY DESC(?trials) ASC(?intervention)
Isso nos dá:
| intervention | trials |
| Hidroxicloroquina (edit) | 43 |
| cloroquina (edit) | 15 |
| lopinavir (edit) | 15 |
| ritonavir (edit) | 15 |
| Chloroquine diphosphate bearing dextran nanoparticles augmented drug delivery and overwhelmed drug resistance in Plasmodium falciparum parasites (edit) | 12 |
| tocilizumabe (edit) | 6 |
| interferon (edit) | 4 |
| óxido nítrico (edit) | 4 |
| antiviral agent (edit) | 4 |
| losartan (edit) | 4 |
| paracetamol (edit) | 4 |
| prednisolona (edit) | 3 |
| azitromicina (edit) | 3 |
| null sparql/clinicalTrialsByIntervention.rq | |
É importante destacar que essa lista só dá uma ideia de quais intervenções tiveram mais atenção que as outras. É essencial perceber que atenção NÃO é uma medida de sucesso.