SARS-CoV-2の問題に対して現状では解決方法がありません。
しかし、解決方法になりうるアイデアは幾つかあります。ワクチンがその一つですが、その開発には時間を要します[1]。 また、抗体や、SARS-CoV-2にも有効である既存の薬、つまり既存薬再開発についての議論もされていますが、現在これらは全て研究段階です。 そして、臨床試験は重要です（臨床試験を参照）。
本章では、解決に繋がりそうな提案に関する、Wikidataに収められている情報を取得するクエリを幾つか提示します。
抗体は関心を集めつつあります。次のクエリ集はヒトコロナウイルスについての文献で、抗体という注釈がつけられているものを取得します。
SPARQL sparql/antibodies.rq (実行, 編集)
SELECT ?virus ?virusLabel ?work ?workLabel WITH {
SELECT ?virus ?work WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?work wdt:P921 ?virus ;
wdt:P921 wd:Q79460 .
}
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
}
ORDER BY ?virusLabel ?virus ?workLabel ?work
このクエリの結果は長くなるので、それぞれのウイルスに対する抗体についての論文数を見てみましょう。
| virus | count |
| SARS関連コロナウイルス (edit) | 48 |
| MERSコロナウイルス (edit) | 16 |
| SARSコロナウイルス2 (edit) | 13 |
| ヒトコロナウイルス229E (edit) | 2 |
| ベータコロナウイルス１ (edit) | 1 |
なお、抗体は個々のタンパク質に特化しているものであり、そして全てのコロナウイルスは異なるタンパク質を持ちます。 ですから、このクエリ集は単に読むべき関連論文を取得するためのショートカットであり、決してそこから結論を導き出すものではないことを強調しておきます。
いつかは、SARS-CoV-2から我々を守ってくれるワクチンが得られるかもしれません。 現時点で幾つかの候補が研究されています[2]。 それらのうち、Wikidataに収められているものを以下のクエリで取得できます。
SPARQL sparql/vaccines.rq (実行, 編集)
SELECT DISTINCT ?vaccine ?vaccineLabel ?announcement WHERE {
?vaccine wdt:P279 wd:Q87719492 .
OPTIONAL { ?vaccine wdt:P6949 ?announcement . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
} ORDER BY ASC(?vaccine) ASC(?announcement)
現状ではそれほど多くありません。
| vaccine | announcement |
| Sanofi/GSK SARS-CoV-2 subunit vaccine (edit) | |
| UB-612 (edit) | |
| RBD SARS-CoV-2 HBsAg VLP (edit) | |
| Q100532641 (edit) | |
| BriLife (edit) | |
| bacTRL-Spike (edit) | |
| hAd5-S-Fusion+N-ETSD (edit) | |
| VXA-CoV2-1 (edit) | |
| MVC COVID-19 Vaccine (edit) | |
| Valneva COVID-19 vaccine (edit) | |
| SOBERANA 02 (edit) | |
| COVIran Barekat (edit) | |
| QazCovid-in (edit) | |
| This table is truncated. See the full table at sparql/vaccines.rq | |
8.3章で既に臨床試験の概要を取得しました。 そこでは、どのような症状に人は心配するのかについて知見を得られました。 また、どのような薬が既存薬再開発のために研究されているのか知ることができました。 大きな注目を浴びる薬もあれば、それほどでもないものもあります。これらは以下のような感じです。
次のクエリにより、介入による臨床試験の事例一覧が得られます。
SPARQL sparql/clinicalTrialsByIntervention.rq (実行, 編集)
SELECT ?intervention ?interventionLabel (COUNT(?trial) AS ?trials) WHERE {
VALUES ?topic {
wd:Q84263196 wd:Q82069695
}
?trial wdt:P31 wd:Q30612 ;
wdt:P921 ?topic ;
wdt:P4844 ?intervention .
SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
} GROUP BY ?intervention ?interventionLabel
ORDER BY DESC(?trials) ASC(?intervention)
結果は以下のとおりです。
| intervention | trials |
| ヒドロキシクロロキン (edit) | 43 |
| クロロキン (edit) | 15 |
| ロピナビル (edit) | 15 |
| リトナビル (edit) | 15 |
| Chloroquine diphosphate bearing dextran nanoparticles augmented drug delivery and overwhelmed drug resistance in Plasmodium falciparum parasites (edit) | 12 |
| トシリズマブ (edit) | 6 |
| インターフェロン (edit) | 4 |
| 一酸化窒素 (edit) | 4 |
| 抗ウイルス剤 (edit) | 4 |
| ロサルタン (edit) | 4 |
| パラセタモール (edit) | 4 |
| プレドニゾロン (edit) | 3 |
| アジスロマイシン (edit) | 3 |
| This table is truncated. See the full table at sparql/clinicalTrialsByIntervention.rq | |
重要なことは、どのような介入がより多くの注目を集めているかを把握できるに過ぎない、ということです。 そして、注目度が成功度を測る指標ではないと認識することが肝要です。