Since the start of the pandemic, various solutions have been developed. A vaccine is one of them, but development of that takes time [1]. But there are also ideas about antibodies and repurposing of drugs. All this is very much exploratory at this moment. Clinical trials remain important (see the Clinical trials section).
This Chapter shows a number of queries with information in Wikidata about leads that people have proposed that may lead to a solution.
Antibodies are getting an interest. The following query lists articles about the human coronaviruses and also annotated with the term ‘antibody’:
SPARQL sparql/antibodies.rq (run, edit)
SELECT ?virus ?virusLabel ?work ?workLabel WITH {
SELECT ?virus ?work WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?work wdt:P921 ?virus ;
wdt:P921 wd:Q79460 .
}
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
}
ORDER BY ?virusLabel ?virus ?workLabel ?work
The list is getting long, so let’s first show the number of articles about antibodies for each virus:
| virus | count |
| SARSr-CoV (edit) | 48 |
| Middle East respiratory syndrome coronavirus (edit) | 16 |
| SARS-CoV-2 (edit) | 13 |
| Human coronavirus 229E (edit) | 2 |
| Human coronavirus OC43 (edit) | 1 |
It must be stressed that antibodies are specific for every protein and every coronavirus has different proteins, and this list is just to shortlist relevant literature for reading, not to draw conclusions from:
Over time, several vaccines have been developed that provide us with a level of immunity to protect us against SARS-CoV-2. Many vaccines have been developed now [2]. We can list the vaccines given in Wikidata with this query:
SPARQL sparql/vaccines.rq (run, edit)
SELECT DISTINCT ?vaccine ?vaccineLabel ?announcement WHERE {
?vaccine wdt:P279 wd:Q87719492 .
OPTIONAL { ?vaccine wdt:P6949 ?announcement . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
} ORDER BY ASC(?vaccine) ASC(?announcement)
It currently list not many:
| vaccine | announcement |
| Sanofi/GSK SARS-CoV-2 subunit vaccine (edit) | |
| UB-612 (edit) | |
| RBD SARS-CoV-2 HBsAg VLP (edit) | |
| Q100532641 (edit) | |
| BriLife (edit) | |
| bacTRL-Spike (edit) | |
| hAd5-S-Fusion+N-ETSD (edit) | |
| VXA-CoV2-1 (edit) | |
| MVC COVID-19 Vaccine (edit) | |
| Valneva COVID-19 vaccine (edit) | |
| SOBERANA 02 (edit) | |
| COVIran Barekat (edit) | |
| QazCovid-in (edit) | |
| This table is truncated. See the full table at sparql/vaccines.rq | |
While far from complete, clinical trials registered in clinicaltrials.gov are finding their way into Wikidata. The following query lists a number of clinical trials with COVID-19 as main topic:
SPARQL sparql/clinicalTrials.rq (run, edit)
SELECT ?trial ?trialLabel ?intervention ?interventionLabel ?phase ?phaseLabel ?identifier WITH {
SELECT DISTINCT ?trial ?phase ?identifier WHERE {
VALUES ?topic { wd:Q84263196 wd:Q82069695 }
?trial wdt:P31 wd:Q30612 ;
wdt:P921 ?topic ;
wdt:P6099 ?phase ;
wdt:P3098 ?identifier .
}
} AS %TRIALS {
INCLUDE %TRIALS
OPTIONAL {
?trial wdt:P4844 ?intervention .
}
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
} ORDER BY DESC(?identifier) ASC(?intervention)
This lists has become very long, and click one of the above links to list them all, and only 15 are given here:
The Section 8.3 already listed an overview of clinical trials. It gives an idea of what symptoms people are worried about. It also gives insight in what drugs are studied for repurposing. Some of these have received a lot of attention, others less so. They look like this:
The following query lists the number of clinical trials by intervention:
SPARQL sparql/clinicalTrialsByIntervention.rq (run, edit)
SELECT ?intervention ?interventionLabel (COUNT(?trial) AS ?trials) WHERE {
VALUES ?topic {
wd:Q84263196 wd:Q82069695
}
?trial wdt:P31 wd:Q30612 ;
wdt:P921 ?topic ;
wdt:P4844 ?intervention .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
} GROUP BY ?intervention ?interventionLabel
ORDER BY DESC(?trials) ASC(?intervention)
This gives:
| intervention | trials |
| hydroxychloroquine (edit) | 43 |
| chloroquine (edit) | 15 |
| lopinavir (edit) | 15 |
| ritonavir (edit) | 15 |
| Chloroquine diphosphate bearing dextran nanoparticles augmented drug delivery and overwhelmed drug resistance in Plasmodium falciparum parasites (edit) | 12 |
| tocilizumab (edit) | 6 |
| interferon (edit) | 4 |
| nitric oxide (edit) | 4 |
| antiviral agent (edit) | 4 |
| losartan (edit) | 4 |
| paracetamol (edit) | 4 |
| prednisolone (edit) | 3 |
| azithromycin (edit) | 3 |
| This table is truncated. See the full table at sparql/clinicalTrialsByIntervention.rq | |
Importantly, this list only gives an idea of what intervention have received more attention than others. And it is essential to realize that attention is not a measure of success.