Comprender los procesos biológicos por los cuales funciona el virión CoV requiere conocer qué genes y proteínas humanos están involucrados. Esto es hacia la siguiente sección, por supuesto, es posible que primero deseemos saber qué dice la literatura aquí (la anotación aún es limitada):
SPARQL sparql/humanInteractionCounts.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?gene ?geneLabel ?count WITH {
SELECT ?virus ?gene (COUNT(DISTINCT ?work) AS ?count) WHERE {
?virus wdt:P171+ wd:Q57751738 .
?work wdt:P921 ?virus, ?gene .
?gene wdt:P703 wd:Q15978631 .
{ ?gene wdt:P31 wd:Q7187 } UNION { ?gene wdt:P31 wd:Q8054 }
} GROUP BY ?virus ?gene
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
ORDER BY DESC(?count) ?virus ?gene
Esto nos da estos números de documentos:
Si desea ver los documentos específicos (una lista creciente), use esta consulta:
SPARQL sparql/humanInteractions.rq (ejecutar, editar)
SELECT ?date ?virus ?virusLabel ?gene ?geneLabel ?work ?workLabel ?doi WITH {
SELECT (MAX(?dates) as ?date) ?virus ?gene ?work WHERE {
?virus wdt:P171+ wd:Q57751738 .
?work wdt:P921 ?virus, ?gene .
OPTIONAL { ?work wdt:P577 ?dates . }
?gene wdt:P703 wd:Q15978631 .
{ ?gene wdt:P31 wd:Q7187 } UNION { ?gene wdt:P31 wd:Q8054 }
} GROUP BY ?virus ?gene ?work
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
OPTIONAL { ?work wdt:P356 ?doi . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
ORDER BY DESC(?date) ?doi ?virus ?gene
WikiPathways [1] es uno de los proyectos involucrados en el esfuerzo de curación internacional de #covidpathways COVID-19 y las contribuciones de WikiPathways se pueden encontrar en este portal.
Vías moleculares de Reactome [2] y WikiPathways están indexadas en Wikidata, y podemos consultar las vías que tienen genes y proteínas de coronavirus humanos:
SPARQL sparql/pathways.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?thing ?thingLabel ?pathway ?pathwayLabel WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?thing wdt:P703 ?virus .
?pathway wdt:P31 wd:Q4915012 ; wdt:P527 ?thing .
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} ORDER BY ASC(?virus) ASC(?thing) ASC(?pathway)
Actualmente, esto enumera las siguientes vías, pero con la curación activa, se espera que también crezca rápidamente: