Om de biologische processen van het virusdeeltje te begrijpen, is het nodig te weten welke menselijke genen en eiwitten er bij betrokken zijn. In het volgende onderdeel gaan we verder op de biologische processions in, maar we kunnen eerst kijken naar de literatuur hier over te zeggen heeft (er is maar beperkte onderwerpannotatie):
SPARQL sparql/humanInteractionCounts.rq (uitvoeren, bewerken)
SELECT ?virus ?virusLabel ?gene ?geneLabel ?count WITH {
SELECT ?virus ?gene (COUNT(DISTINCT ?work) AS ?count) WHERE {
?virus wdt:P171+ wd:Q57751738 .
?work wdt:P921 ?virus, ?gene .
?gene wdt:P703 wd:Q15978631 .
{ ?gene wdt:P31 wd:Q7187 } UNION { ?gene wdt:P31 wd:Q8054 }
} GROUP BY ?virus ?gene
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
}
ORDER BY DESC(?count) ?virus ?gene
Dit geeft de volgende aantallen artikelen:
Om te zien om welke artikelen het nu eigenlijk gaat, kunnen we deze zoekopdracht gebruiken:
SPARQL sparql/humanInteractions.rq (uitvoeren, bewerken)
SELECT ?date ?virus ?virusLabel ?gene ?geneLabel ?work ?workLabel ?doi WITH {
SELECT (MAX(?dates) as ?date) ?virus ?gene ?work WHERE {
?virus wdt:P171+ wd:Q57751738 .
?work wdt:P921 ?virus, ?gene .
OPTIONAL { ?work wdt:P577 ?dates . }
?gene wdt:P703 wd:Q15978631 .
{ ?gene wdt:P31 wd:Q7187 } UNION { ?gene wdt:P31 wd:Q8054 }
} GROUP BY ?virus ?gene ?work
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
OPTIONAL { ?work wdt:P356 ?doi . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
}
ORDER BY DESC(?date) ?doi ?virus ?gene
WikiPathways [1] is een van de projecten dat betrokken is bij het internationale #covidpathways COVID-19 curatie project en haar bijdragen kunnen gevonden worden op deze portal.
Reactome [2] en WikiPathways reactiepaden worden geïndexeerd in Wikidata en we kunnen de reactiepaden waar HCoV genen en eiwitten genoemd worden opzoeken:
SPARQL sparql/pathways.rq (uitvoeren, bewerken)
SELECT ?virus ?virusLabel ?thing ?thingLabel ?pathway ?pathwayLabel WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?thing wdt:P703 ?virus .
?pathway wdt:P31 wd:Q4915012 ; wdt:P527 ?thing .
SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
} ORDER BY ASC(?virus) ASC(?thing) ASC(?pathway)
Dit laat op dit moment de volgende reactiepaden zien, maar met de actieve curatie is het te verwachten dat dit snel toeneemt: