Compreender os processos biológicos pelos quais o SARS-CoV-2 funciona requer saber quais genes e proteínas humanos estão envolvidos. Isso é para a próxima seção podemos primeiro querer saber o que a literatura diz aqui (a anotação ainda é limitada):
SPARQL sparql/humanInteractionCounts.rq (run, edit)
SELECT ?virus ?virusLabel ?gene ?geneLabel ?count WITH {
SELECT ?virus ?gene (COUNT(DISTINCT ?work) AS ?count) WHERE {
?virus wdt:P171+ wd:Q57751738 .
?work wdt:P921 ?virus, ?gene .
?gene wdt:P703 wd:Q15978631 .
{ ?gene wdt:P31 wd:Q7187 } UNION { ?gene wdt:P31 wd:Q8054 }
} GROUP BY ?virus ?gene
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
ORDER BY DESC(?count) ?virus ?gene
Isso nos dá esse número de documentos:
Se você quiser ver os documentos específicos (uma lista crescente), use esta consulta:
SPARQL sparql/humanInteractions.rq (run, edit)
SELECT ?date ?virus ?virusLabel ?gene ?geneLabel ?work ?workLabel ?doi WITH {
SELECT (MAX(?dates) as ?date) ?virus ?gene ?work WHERE {
?virus wdt:P171+ wd:Q57751738 .
?work wdt:P921 ?virus, ?gene .
OPTIONAL { ?work wdt:P577 ?dates . }
?gene wdt:P703 wd:Q15978631 .
{ ?gene wdt:P31 wd:Q7187 } UNION { ?gene wdt:P31 wd:Q8054 }
} GROUP BY ?virus ?gene ?work
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
OPTIONAL { ?work wdt:P356 ?doi . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
ORDER BY DESC(?date) ?doi ?virus ?gene
WikiPathways [1] é um dos projetos envolvidos no esforço internacional de curadoria dos #covidpathways COVID-19 e as contribuições de WikiPathways podem ser encontradas neste portal.
As vias moleculares do Reactome [2] e do WikiPathways estão indexadas no Wikidata e podemos consultar as que apresentam genes e proteínas de coronavírus humanos:
SPARQL sparql/pathways.rq (run, edit)
SELECT ?virus ?virusLabel ?thing ?thingLabel ?pathway ?pathwayLabel WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?thing wdt:P703 ?virus .
?pathway wdt:P31 wd:Q4915012 ; wdt:P527 ?thing .
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY ASC(?virus) ASC(?thing) ASC(?pathway)
Atualmente, essa busca enumera as seguintes vias (mas espera-se que com a curadoria ativa, esse número cresça rapidamente):