CoV粒子の働きによる生体内の作用を理解するためには、どのヒト遺伝子およびタンパク質が関わっているのかを知る必要があります。これは次の節のためですが、まずはどの文献で述べられているのかここで調べましょう（アノテーションは依然として限られています）。
SPARQL sparql/humanInteractionCounts.rq (実行, 編集)
SELECT ?virus ?virusLabel ?gene ?geneLabel ?count WITH {
SELECT ?virus ?gene (COUNT(DISTINCT ?work) AS ?count) WHERE {
?virus wdt:P171+ wd:Q57751738 .
?work wdt:P921 ?virus, ?gene .
?gene wdt:P703 wd:Q15978631 .
{ ?gene wdt:P31 wd:Q7187 } UNION { ?gene wdt:P31 wd:Q8054 }
} GROUP BY ?virus ?gene
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
}
ORDER BY DESC(?count) ?virus ?gene
このクエリにより、これらの文献が得られます。
特定の論文群（増え続けるリスト）を見たい場合は、このクエリを試しましょう。
SPARQL sparql/humanInteractions.rq (実行, 編集)
SELECT ?date ?virus ?virusLabel ?gene ?geneLabel ?work ?workLabel ?doi WITH {
SELECT (MAX(?dates) as ?date) ?virus ?gene ?work WHERE {
?virus wdt:P171+ wd:Q57751738 .
?work wdt:P921 ?virus, ?gene .
OPTIONAL { ?work wdt:P577 ?dates . }
?gene wdt:P703 wd:Q15978631 .
{ ?gene wdt:P31 wd:Q7187 } UNION { ?gene wdt:P31 wd:Q8054 }
} GROUP BY ?virus ?gene ?work
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
OPTIONAL { ?work wdt:P356 ?doi . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
}
ORDER BY DESC(?date) ?doi ?virus ?gene
WikiPathways [1]は、国際的な#covidpathways COVID-19 curation effortに参加するプロジェクトです。当該プロジェクトに加わる人々はこのポータルサイトで確認できます。
Reactome [2]とWikiPathwaysのパスウェイはWikidataに索引付されており、HCoV遺伝子およびタンパク質が関わるパスウェイを取得できます。
SPARQL sparql/pathways.rq (実行, 編集)
SELECT ?virus ?virusLabel ?thing ?thingLabel ?pathway ?pathwayLabel WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?thing wdt:P703 ?virus .
?pathway wdt:P31 wd:Q4915012 ; wdt:P527 ?thing .
SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
} ORDER BY ASC(?virus) ASC(?thing) ASC(?pathway)
現在、次のパスウェイが得られますが、活発なキュレーション活動により、次々に増えていくと期待できます。