Understanding the biological processes by which the CoV virion works, requires knowing which human genes and proteins are involved. This is towards the next section of course, but we may first want to know what literature has to say here (annotation is still limited):
SPARQL sparql/humanInteractionCounts.rq (run, edit)
SELECT ?virus ?virusLabel ?gene ?geneLabel ?count WITH {
SELECT ?virus ?gene (COUNT(DISTINCT ?work) AS ?count) WHERE {
?virus wdt:P171+ wd:Q57751738 .
?work wdt:P921 ?virus, ?gene .
?gene wdt:P703 wd:Q15978631 .
{ ?gene wdt:P31 wd:Q7187 } UNION { ?gene wdt:P31 wd:Q8054 }
} GROUP BY ?virus ?gene
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
}
ORDER BY DESC(?count) ?virus ?gene
This gives us these numbers of papers:
If you want to see the specific papers (a growing list), use this query:
SPARQL sparql/humanInteractions.rq (run, edit)
SELECT ?date ?virus ?virusLabel ?gene ?geneLabel ?work ?workLabel ?doi WITH {
SELECT (MAX(?dates) as ?date) ?virus ?gene ?work WHERE {
?virus wdt:P171+ wd:Q57751738 .
?work wdt:P921 ?virus, ?gene .
OPTIONAL { ?work wdt:P577 ?dates . }
?gene wdt:P703 wd:Q15978631 .
{ ?gene wdt:P31 wd:Q7187 } UNION { ?gene wdt:P31 wd:Q8054 }
} GROUP BY ?virus ?gene ?work
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
OPTIONAL { ?work wdt:P356 ?doi . }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
}
ORDER BY DESC(?date) ?doi ?virus ?gene
WikiPathways [1] is one of the projects involved in the international #covidpathways COVID-19 curation effort and the WikiPathways contributions can be found on this portal.
Reactome [2] and WikiPathways pathways are indexed in Wikidata, and we can query for pathways that have HCoV genes and proteins in their pathways:
SPARQL sparql/pathways.rq (run, edit)
SELECT ?virus ?virusLabel ?thing ?thingLabel ?pathway ?pathwayLabel WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?thing wdt:P703 ?virus .
?pathway wdt:P31 wd:Q4915012 ; wdt:P527 ?thing .
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
} ORDER BY ASC(?virus) ASC(?thing) ASC(?pathway)
This currently lists the following pathways, but with the active curation, it is expected to grow quickly too: