Los coronavirus no son nuevos y algunos de ellos son bastante inofensivos. Por ejemplo, los coronavirus humanos HCoV-229E y HCoV-OC43 normalmente dan como resultado un resfriado común [1]. Sin embargo, para los coronavirus relacionados con el síndrome respiratorio agudo graves (coronavirus relacionado con el SARS), esto es diferente. SARS-CoV-2, por supuesto, es el tema principal de este libro [2].
El virus SARS-CoV-2 no es el primer coronavirus (CoV). De hecho, se conocen bastantes CoV relacionados con el SARS, como se mensiona en esta Lista de taxonomía de NCBI.
Primero enumeramos todos los virus SARSr-CoV en Wikidata:
SPARQL sparql/allSARSCoVViruses.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q278567 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
Esto nos da:
| virus | ncbi |
| SL-CoV-WIV1 (edit) | 1415852 |
| SARS-CoV-2 (edit) | 2697049 |
| SARS-CoV (edit) | |
| SHC014-CoV (edit) | 1415851 |
| Bat SARS coronavirus Rp1 (edit) | 349342 |
| SARS coronavirus B024 (edit) | 305407 |
| RaTG13 (edit) | 2709072 |
| Bat SARS CoV Rf1/2004 (edit) | 347537 |
| Bat SARS CoV Rm1/2004 (edit) | 347536 |
| Bat SARS CoV Rp3/2004 (edit) | 349344 |
| RmYN02 (edit) | |
| Civet SARS-CoV (edit) | |
| RacCS203 (edit) | |
| Rc-o319 (edit) | |
| 16BO133 (edit) | |
| BtKY72 (edit) | |
| BM48-31 (edit) | |
| RpYN06 (edit) | |
| RhGB01 (edit) | |
| BANAL-52 (edit) | |
| BANAL-103 (edit) |
Si comparamos esta lista con la de la Sección 2.2, no es que estas dos listas no se superpongan completamente.
Sin embargo, para la pandemia actual, los siete coronavirus humanos pueden ser de particular interés [3].
Podemos usar esta consulta para enumerar estos:
SPARQL sparql/humanCoronaviruses.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?ncbi WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
Esto nos da un buen punto de partida para estudiar el virus con más detalladamente:
Pero los coronavirus relacionados con el SARS son solo un subgrupo. Otro subgrupo de coronavirus es el de los betacoronavirus:
SPARQL sparql/allBetacoronaViruses.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q16532287 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} ORDER BY ?virusLabel
Debido a que hay bastantes en Wikidata, preferimos hacer un gráfico de dependencia:
SPARQL sparql/allBetacoronaVirusesGraph.rq (ejecutar, editar)
#defaultView:Graph
SELECT ?parent ?parentLabel ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q16532287 .
?virus wdt:P171 ?parent .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
Esto da la siguiente salida:
La lista completa de coronavirus se ve así:
SPARQL sparql/allCoronaViruses.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q57751738 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} ORDER BY ASC(?virus)
Nuevamente, preferimos hacer un gráfico de dependencia de gráficos:
SPARQL sparql/allCoronaVirusesGraph.rq (ejecutar, editar)
#defaultView:Graph
SELECT ?parent ?parentLabel ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q57751738 .
?virus wdt:P171 ?parent .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
} ORDER BY ASC(?parent) ASC(?virus)
Esto da la siguiente salida:
También podemos consultar artículos que comparen un coronavirus humano con otro coronavirus:
SPARQL sparql/compareViruses.rq (ejecutar, editar)
SELECT DISTINCT ?virus ?virusLabel ?work ?workLabel WITH {
SELECT DISTINCT ?virus ?virus2 ?work WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?virus2 wdt:P171+ wd:Q57751738 .
?work wdt:P921 ?virus, ?virus2 .
FILTER ( ?virus != ?virus2 )
}
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
ORDER BY ?virusLabel ?virus ?workLabel ?work
Para los coronavirus podemos enumerar los identificadores NCBI Taxonomy [4] con:
SPARQL sparql/allSARSCoVVirusesTaxonomy.rq (ejecutar, editar)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q278567 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "es,en". }
}
Esto nos da:
| virus | ncbi |
| SL-CoV-WIV1 (edit) | 1415852 |
| SARS-CoV-2 (edit) | 2697049 |
| SARS-CoV (edit) | |
| SHC014-CoV (edit) | 1415851 |
| Bat SARS coronavirus Rp1 (edit) | 349342 |
| SARS coronavirus B024 (edit) | 305407 |
| RaTG13 (edit) | 2709072 |
| Bat SARS CoV Rf1/2004 (edit) | 347537 |
| Bat SARS CoV Rm1/2004 (edit) | 347536 |
| Bat SARS CoV Rp3/2004 (edit) | 349344 |
| RmYN02 (edit) | |
| Civet SARS-CoV (edit) | |
| RacCS203 (edit) | |
| Rc-o319 (edit) | |
| 16BO133 (edit) | |
| BtKY72 (edit) | |
| BM48-31 (edit) | |
| RpYN06 (edit) | |
| RhGB01 (edit) | |
| BANAL-52 (edit) | |
| BANAL-103 (edit) |