Coronavirussen zijn niet nieuw en sommige zijn niet echt gevaarlijk. De menselijke coronavirusen HCoV-229E en HCoV-OC42 veroorzaken namelijk normaal alleen een verkoudheid [1]. Echter, voor de severe acute respiratory syndrome-gerelateerde coronavirussen (SARSr virussen) is dat anders. Want SARS-CoV-2 is het hoofdonderwerp van dit boek.
Het SARS-CoV-2 virus is niet het eerste coronavirus (CoV). Er zijn namelijk behoorlijk veel SARS-gerelateerde CoVs bekend, zoals duidelijk is in deze NCBI Taxonomy lijst.
Laten we eerste alle SARSr-CoV virussen in Wikidata opzoeken:
SPARQL sparql/allSARSCoVViruses.rq (uitvoeren, bewerken)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q278567 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
}
Dit geeft ons:
Als we dit vergelijken met de lijst in Sectie 2.2, dan zien we dat deze twee lijsten niet helemaal overlappen.
Maar voor de huidige pandemie zijn deze zeven menselijke coronavirusen relevanter [2]. We kunnen de volgende zoekopdracht gebruiken om alleen deze te laten zien:
SPARQL sparql/humanCoronaviruses.rq (uitvoeren, bewerken)
SELECT ?virus ?virusLabel ?ncbi WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
}
Dat geeft ons een goed startpunt om het virus in meer detail te bekijken:
Maar de SARS-gerelateerde coronevirussen zijn maar een mogelijke subgroep. Een andere groep is die van de betacoronavirusen:
SPARQL sparql/allBetacoronaViruses.rq (uitvoeren, bewerken)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q16532287 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
} ORDER BY ?virusLabel
Omdat Wikidata behoorlijk veel van deze virussen beschrijft, kunnen we beter een netwerkvisualisaite maken:
SPARQL sparql/allBetacoronaVirusesGraph.rq (uitvoeren, bewerken)
#defaultView:Graph
SELECT ?parent ?parentLabel ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q16532287 .
?virus wdt:P171 ?parent .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
}
Dat geeft dit:
De volledige lijst van alle coronavirusen kunnen we opvragen met deze zoekopdracht:
SPARQL sparql/allCoronaViruses.rq (uitvoeren, bewerken)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q57751738 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
} ORDER BY ASC(?virus)
Opnieuw, deze visualiseren we liever als een netwerk:
SPARQL sparql/allCoronaVirusesGraph.rq (uitvoeren, bewerken)
#defaultView:Graph
SELECT ?parent ?parentLabel ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q57751738 .
?virus wdt:P171 ?parent .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
} ORDER BY ASC(?parent) ASC(?virus)
Dat geeft deze uitkomsten:
We kunnen ook artikelen opvragen die menselijke coronavirussen vergelijken met andere coronavirussen:
SPARQL sparql/compareViruses.rq (uitvoeren, bewerken)
SELECT DISTINCT ?virus ?virusLabel ?work ?workLabel WITH {
SELECT DISTINCT ?virus ?virus2 ?work WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?virus2 wdt:P171+ wd:Q57751738 .
?work wdt:P921 ?virus, ?virus2 .
FILTER ( ?virus != ?virus2 )
}
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
}
ORDER BY ?virusLabel ?virus ?workLabel ?work
Voor de coronavirussen kunnen we ook de NCBI Taxonomie [3] nummers opvragen met:
SPARQL sparql/allSARSCoVVirusesTaxonomy.rq (uitvoeren, bewerken)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q278567 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
}
Dat geeft: