SARS-CoV-2-Queries

[ en ja nl es pt ]

Virussen

Coronavirussen zijn niet nieuw en sommige zijn niet echt gevaarlijk. De menselijke coronavirusen HCoV-229E en HCoV-OC42 veroorzaken namelijk normaal alleen een verkoudheid [1]. Echter, voor de severe acute respiratory syndrome-gerelateerde coronavirussen (SARSr virussen) is dat anders. Want SARS-CoV-2 is het hoofdonderwerp van dit boek.

Alle SARS-gerelateerde virussen

Het SARS-CoV-2 virus is niet het eerste coronavirus (CoV). Er zijn namelijk behoorlijk veel SARS-gerelateerde CoVs bekend, zoals duidelijk is in deze NCBI Taxonomy lijst.

Laten we eerste alle SARSr-CoV virussen in Wikidata opzoeken:

SPARQL sparql/allSARSCoVViruses.rq (uitvoeren, bewerken)

SELECT ?virus ?virusLabel ?ncbi WHERE {
  ?virus wdt:P171+ wd:Q278567 .
  OPTIONAL { ?virus wdt:P685 ?ncbi }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
}

Dit geeft ons:

virus ncbi
SL-CoV-WIV1 (edit) 1415852
SARS-CoV-2 (edit) 2697049
severe acute respiratory syndrome coronavirus (edit)
Bat SARS-like coronavirus RsSHC014 (edit) 1415851
Bat SARS coronavirus Rp1 (edit) 349342
SARS coronavirus B024 (edit) 305407
Bat coronavirus RaTG13 (edit) 2709072
Bat SARS CoV Rf1 (edit) 347537
Bat SARS CoV Rm1 (edit) 347536
Bat SARS CoV Rp3 (edit) 349344
501.V2-variant (edit)
Civet SARS-CoV (edit)
RacCS203 (edit)
Rc-o319 (edit)
BtKY72 (edit)
BM48-31 (edit)

Als we dit vergelijken met de lijst in Sectie 2.2, dan zien we dat deze twee lijsten niet helemaal overlappen.

De zeven coronavirusen die mensen infecteren

Maar voor de huidige pandemie zijn deze zeven menselijke coronavirusen relevanter [2]. We kunnen de volgende zoekopdracht gebruiken om alleen deze te laten zien:

SPARQL sparql/humanCoronaviruses.rq (uitvoeren, bewerken)

SELECT ?virus ?virusLabel ?ncbi WHERE {
  VALUES ?virus {
    wd:Q82069695 # SARS-CoV-2
    wd:Q16983360 # HKU1
    wd:Q16991954 # OC43
    wd:Q8351095  # NL63 
    wd:Q16983356 # 229E
    wd:Q4902157  # MERS-CoV
    wd:Q278567   # SARS-CoV
  }
  OPTIONAL { ?virus wdt:P685 ?ncbi }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
}

Dat geeft ons een goed startpunt om het virus in meer detail te bekijken:

virus ncbi
SARS-virus (edit) 694009
SARS-virus (edit) 227859
Middle East respiratory syndrome coronavirus (edit) 1335626
Menselijk Coronavirus NL63 (edit) 277944
Menselijk coronavirus 229E (edit) 11137
Menselijk coronavirus HKU1 (edit) 290028
Menselijk coronavirus OC43 (edit) 31631
SARS-CoV-2 (edit) 2697049

Alle betacoronavirusen

Maar de SARS-gerelateerde coronevirussen zijn maar een mogelijke subgroep. Een andere groep is die van de betacoronavirusen:

SPARQL sparql/allBetacoronaViruses.rq (uitvoeren, bewerken)

SELECT ?virus ?virusLabel ?ncbi WHERE {
  ?virus wdt:P171+ wd:Q16532287 .
  OPTIONAL { ?virus wdt:P685 ?ncbi }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
} ORDER BY ?virusLabel

Omdat Wikidata behoorlijk veel van deze virussen beschrijft, kunnen we beter een netwerkvisualisaite maken:

SPARQL sparql/allBetacoronaVirusesGraph.rq (uitvoeren, bewerken)

#defaultView:Graph
SELECT ?parent ?parentLabel ?virus ?virusLabel ?ncbi WHERE {
  ?virus wdt:P171+ wd:Q16532287 .
  ?virus wdt:P171 ?parent .
  OPTIONAL { ?virus wdt:P685 ?ncbi }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
}

Dat geeft dit:

Alle coronavirusen

De volledige lijst van alle coronavirusen kunnen we opvragen met deze zoekopdracht:

SPARQL sparql/allCoronaViruses.rq (uitvoeren, bewerken)

SELECT ?virus ?virusLabel ?ncbi WHERE {
  ?virus wdt:P171+ wd:Q57751738 .
  OPTIONAL { ?virus wdt:P685 ?ncbi }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
} ORDER BY ASC(?virus)

Opnieuw, deze visualiseren we liever als een netwerk:

SPARQL sparql/allCoronaVirusesGraph.rq (uitvoeren, bewerken)

#defaultView:Graph
SELECT ?parent ?parentLabel ?virus ?virusLabel ?ncbi WHERE {
  ?virus wdt:P171+ wd:Q57751738 .
  ?virus wdt:P171 ?parent .
  OPTIONAL { ?virus wdt:P685 ?ncbi }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
} ORDER BY ASC(?parent) ASC(?virus)

Dat geeft deze uitkomsten:

Virussen vergelijken

We kunnen ook artikelen opvragen die menselijke coronavirussen vergelijken met andere coronavirussen:

SPARQL sparql/compareViruses.rq (uitvoeren, bewerken)

SELECT DISTINCT ?virus ?virusLabel ?work ?workLabel WITH {
  SELECT DISTINCT ?virus ?virus2 ?work WHERE {
    VALUES ?virus {
      wd:Q82069695 # SARS-CoV-2
      wd:Q16983360 # HKU1
      wd:Q16991954 # OC43
      wd:Q8351095  # NL63 
      wd:Q16983356 # 229E 
      wd:Q4902157  # MERS-CoV
      wd:Q278567   # SARS-CoV
    }
    ?virus2 wdt:P171+ wd:Q57751738 .
    ?work wdt:P921 ?virus, ?virus2 .
    FILTER ( ?virus != ?virus2 )
  }
} AS %ARTICLES WHERE {
  INCLUDE %ARTICLES
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
}
ORDER BY ?virusLabel ?virus ?workLabel ?work

NCBI Taxonomie nummers

Voor de coronavirussen kunnen we ook de NCBI Taxonomie [3] nummers opvragen met:

SPARQL sparql/allSARSCoVVirusesTaxonomy.rq (uitvoeren, bewerken)

SELECT ?virus ?virusLabel ?ncbi WHERE {
  ?virus wdt:P171+ wd:Q278567 .
  OPTIONAL { ?virus wdt:P685 ?ncbi }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "nl,en". }
}

Dat geeft:

virus ncbi
SL-CoV-WIV1 (edit) 1415852
SARS-CoV-2 (edit) 2697049
severe acute respiratory syndrome coronavirus (edit)
Bat SARS-like coronavirus RsSHC014 (edit) 1415851
Bat SARS coronavirus Rp1 (edit) 349342
SARS coronavirus B024 (edit) 305407
Bat coronavirus RaTG13 (edit) 2709072
Bat SARS CoV Rf1 (edit) 347537
Bat SARS CoV Rm1 (edit) 347536
Bat SARS CoV Rp3 (edit) 349344
501.V2-variant (edit)
Civet SARS-CoV (edit)
RacCS203 (edit)
Rc-o319 (edit)
BtKY72 (edit)
BM48-31 (edit)

Bronnen

  1. Pyrc K, Berkhout B, van der Hoek L. The novel human coronaviruses NL63 and HKU1. J Virol. 2006 Nov 1;81(7):3051–7. doi:10.1128/JVI.01466-06 (Scholia)
  2. Zhu N, Zhang D, Wang W, Li X, Yang B, Song J, et al. A Novel Coronavirus from Patients with Pneumonia in China, 2019. NEJM [Internet]. 2020 Feb 20;382(8):727–33. Available from: https://www.ncbi.nlm.nih.gov/pmc/articles/PMC7092803/ doi:10.1056/NEJMOA2001017 (Scholia)
  3. Federhen S. The NCBI Taxonomy database. NAR. 2012 Jan;40(Database issue):D136-43. doi:10.1093/NAR/GKR1178 (Scholia)