Coronaviruses are not new and some of them are pretty harmless. For example, the human coronaviruses HCoV-229E and HCoV-OC43 normally result in a common cold [1]. However, for the severe acute respiratory syndrome-related coronaviruses (SARSr viruses) this is different. SARS-CoV-2, of course, is the main topic of this book [2].
The SARS-CoV-2 virus is not the first coronavirus (CoV). In fact, quite a few SARS-related CoVs are known, as clear from this NCBI Taxonomy list [3,4].
We first list all the SARSr-CoV viruses in Wikidata:
SPARQL sparql/allSARSCoVViruses.rq (run, edit)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q278567 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
}
This gives us:
If we compare this list with that in Section 2.2 we note that these two lists do not fully overlap.
However, for the current pandemic, the seven human corona viruses may be of particular interest [5]. We can use this query to just list these:
SPARQL sparql/humanCoronaviruses.rq (run, edit)
SELECT ?virus ?virusLabel ?ncbi WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
}
This gives us a good starting point to study the virus in more detail:
But the SARS-related coronavirusses is just a subgroup. Another subgroup of coronaviruses is that of the betacoronaviruses:
SPARQL sparql/allBetacoronaViruses.rq (run, edit)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q16532287 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
} ORDER BY ?virusLabel
Because there are quite a few of them in Wikidata, we rather make a graph dependency plot:
SPARQL sparql/allBetacoronaVirusesGraph.rq (run, edit)
#defaultView:Graph
SELECT ?parent ?parentLabel ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q16532287 .
?virus wdt:P171 ?parent .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
}
This gives this output:
The full list of coronaviruses looks like this:
SPARQL sparql/allCoronaViruses.rq (run, edit)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q57751738 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
} ORDER BY ASC(?virus)
Again, we rather make a graph dependency plot:
SPARQL sparql/allCoronaVirusesGraph.rq (run, edit)
#defaultView:Graph
SELECT ?parent ?parentLabel ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q57751738 .
?virus wdt:P171 ?parent .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
} ORDER BY ASC(?parent) ASC(?virus)
This gives this output:
We can also query for articles that compare a human coronavirus with another coronavirus:
SPARQL sparql/compareViruses.rq (run, edit)
SELECT DISTINCT ?virus ?virusLabel ?work ?workLabel WITH {
SELECT DISTINCT ?virus ?virus2 ?work WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?virus2 wdt:P171+ wd:Q57751738 .
?work wdt:P921 ?virus, ?virus2 .
FILTER ( ?virus != ?virus2 )
}
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
}
ORDER BY ?virusLabel ?virus ?workLabel ?work
For the coronaviruses we can list the NCBI Taxonomy [3,4] identifiers with:
SPARQL sparql/allSARSCoVVirusesTaxonomy.rq (run, edit)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q278567 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "en,en". }
}
This gives us: