SARS-CoV-2-Queries

[ en ja nl es pt ]

Virus

Os coronavírus, como grupo, não são novos, e alguns deles são um tanto quanto inofensivos. Por exemplo, os coronavírus humanos HCoV-229E e HCoV-OC43 normalmente causam apenas resultado um resfriado comum [1]. Por outro lado, para os coronavirus relacionados ao vírus da SARS isso é diferente. Entre eles encontra-se o SARS-CoV-2, claro, que é o tema principal deste livro [2].

Todos os coronavírus relacionados com a SARS

O virus SARS-CoV-2 não é o primeiro coronavirus (CoV). De fato, se conhecem muitos coronavírus relacionados com o vírus da SARS, como se meciona nesta Lista de taxonomia do NCBI.

Primeiro enumeramos todos os virus SARSr-CoV no Wikidata:

SPARQL sparql/allSARSCoVViruses.rq (run, edit)

SELECT ?virus ?virusLabel ?ncbi WHERE {
  ?virus wdt:P171+ wd:Q278567 .
  OPTIONAL { ?virus wdt:P685 ?ncbi }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}

Isso nos dá:

virus ncbi
Bat SARS-like coronavirus WIV1 (edit) 1415852
coronavírus da síndrome respiratória aguda grave 2 (edit) 2697049
SARS-CoV-1 (edit)
Bat SARS-like coronavirus RsSHC014 (edit) 1415851
Bat SARS coronavirus Rp1 (edit) 349342
SARS coronavirus B024 (edit) 305407
Bat coronavirus RaTG13 (edit) 2709072
Bat SARS CoV Rf1/2004 (edit) 347537
Bat SARS CoV Rm1/2004 (edit) 347536
Bat SARS CoV Rp3/2004 (edit) 349344
RmYN02 (edit)
Civet SARS-CoV (edit)
RacCS203 (edit)
Rc-o319 (edit)
16BO133 (edit)
BtKY72 (edit)
BM48-31 (edit)
RpYN06 (edit)
RhGB01 (edit)
BANAL-52 (edit)
BANAL-103 (edit)

Se compararmos essa lista com a da seção 2.2, elas não se sobrepõe completamente.

Os sete coronavírus que infectam humanos

Para a pandemia atual, os sete coronavírus humanos podem ser de interesse particular [3].

Podemos usar essa busca para enumerá-los:

SPARQL sparql/humanCoronaviruses.rq (run, edit)

SELECT ?virus ?virusLabel ?ncbi WHERE {
  VALUES ?virus {
    wd:Q82069695 # SARS-CoV-2
    wd:Q16983360 # HKU1
    wd:Q16991954 # OC43
    wd:Q8351095  # NL63 
    wd:Q16983356 # 229E
    wd:Q4902157  # MERS-CoV
    wd:Q278567   # SARS-CoV
  }
  OPTIONAL { ?virus wdt:P685 ?ncbi }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}

Isso nos dá um bom ponto de partida para estudá-los:

virus ncbi
SARS-CoV (edit) 694009
SARS-CoV (edit) 227859
coronavírus da síndrome respiratória do Oriente Médio (edit) 1335626
Coronavírus humano NL63 (edit) 277944
Coronavírus humano 229E (edit) 11137
Coronavírus humano HKU1 (edit) 290028
Coronavírus humano OC43 (edit) 31631
coronavírus da síndrome respiratória aguda grave 2 (edit) 2697049

Todos os betacoronavirus

Mas todos os coronavírus relacionados com o SARS são só um dos subgrupos. Outro subgrupo (que inclui os relacionados a SARS) são os betacoronavirus:

SPARQL sparql/allBetacoronaViruses.rq (run, edit)

SELECT ?virus ?virusLabel ?ncbi WHERE {
  ?virus wdt:P171+ wd:Q16532287 .
  OPTIONAL { ?virus wdt:P685 ?ncbi }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY ?virusLabel

Devido a abundância de dados sobre eles no Wikidata, preferimos fazer um gráfico de dependência:

SPARQL sparql/allBetacoronaVirusesGraph.rq (run, edit)

#defaultView:Graph
SELECT ?parent ?parentLabel ?virus ?virusLabel ?ncbi WHERE {
  ?virus wdt:P171+ wd:Q16532287 .
  ?virus wdt:P171 ?parent .
  OPTIONAL { ?virus wdt:P685 ?ncbi }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}

Que fornece a seguinte saída:

Todos os coronavírus

A lista completa de coronavírus se vê aqui:

SPARQL sparql/allCoronaViruses.rq (run, edit)

SELECT ?virus ?virusLabel ?ncbi WHERE {
  ?virus wdt:P171+ wd:Q57751738 .
  OPTIONAL { ?virus wdt:P685 ?ncbi }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY ASC(?virus)

Novamente, optamos por fazer um gráfico de dependência:

SPARQL sparql/allCoronaVirusesGraph.rq (run, edit)

#defaultView:Graph
SELECT ?parent ?parentLabel ?virus ?virusLabel ?ncbi WHERE {
  ?virus wdt:P171+ wd:Q57751738 .
  ?virus wdt:P171 ?parent .
  OPTIONAL { ?virus wdt:P685 ?ncbi }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY ASC(?parent) ASC(?virus)

Isso nos dá a seguinte saída:

Comparação de diferentes vírus

Também podemos consultar artigos que comparem um coronavírus humano com outros coronavírus.

SPARQL sparql/compareViruses.rq (run, edit)

SELECT DISTINCT ?virus ?virusLabel ?work ?workLabel WITH {
  SELECT DISTINCT ?virus ?virus2 ?work WHERE {
    VALUES ?virus {
      wd:Q82069695 # SARS-CoV-2
      wd:Q16983360 # HKU1
      wd:Q16991954 # OC43
      wd:Q8351095  # NL63 
      wd:Q16983356 # 229E 
      wd:Q4902157  # MERS-CoV
      wd:Q278567   # SARS-CoV
    }
    ?virus2 wdt:P171+ wd:Q57751738 .
    ?work wdt:P921 ?virus, ?virus2 .
    FILTER ( ?virus != ?virus2 )
  }
} AS %ARTICLES WHERE {
  INCLUDE %ARTICLES
  SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
ORDER BY ?virusLabel ?virus ?workLabel ?work

ID de taxonomía de NCBI

ID de taxonomia do NCBI

Para os coronavírus, podemos enumerar os identificadores do NCBI Taxonomy [4] com:

SPARQL sparql/allSARSCoVVirusesTaxonomy.rq (run, edit)

SELECT ?virus ?virusLabel ?ncbi WHERE {
  ?virus wdt:P171+ wd:Q278567 .
  OPTIONAL { ?virus wdt:P685 ?ncbi }
  SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}

Isso nos dá:

virus ncbi
Bat SARS-like coronavirus WIV1 (edit) 1415852
coronavírus da síndrome respiratória aguda grave 2 (edit) 2697049
SARS-CoV-1 (edit)
Bat SARS-like coronavirus RsSHC014 (edit) 1415851
Bat SARS coronavirus Rp1 (edit) 349342
SARS coronavirus B024 (edit) 305407
Bat coronavirus RaTG13 (edit) 2709072
Bat SARS CoV Rf1/2004 (edit) 347537
Bat SARS CoV Rm1/2004 (edit) 347536
Bat SARS CoV Rp3/2004 (edit) 349344
RmYN02 (edit)
Civet SARS-CoV (edit)
RacCS203 (edit)
Rc-o319 (edit)
16BO133 (edit)
BtKY72 (edit)
BM48-31 (edit)
RpYN06 (edit)
RhGB01 (edit)
BANAL-52 (edit)
BANAL-103 (edit)

Referências

  1. Pyrc K, Berkhout B, van der Hoek L. The novel human coronaviruses NL63 and HKU1. J Virol. 2006 Nov 1;81(7):3051–7. doi:10.1128/JVI.01466-06 (Scholia)
  2. Gorbalenya AE, of the International Committee on Taxonomy of Viruses CSG, Baker SC, Drosten C, Haagmans BL, Neuman BW, et al. The species Severe acute respiratory syndrome-related coronavirus: classifying 2019-nCoV and naming it SARS-CoV-2. Nature Microbiology. 2020 Mar 2;5(4):536–44. doi:10.1038/S41564-020-0695-Z (Scholia)
  3. Zhu N, Zhang D, Wang W, Li X, Yang B, Song J, et al. A Novel Coronavirus from Patients with Pneumonia in China, 2019. NEJM [Internet]. 2020 Feb 20;382(8):727–33. Available from: https://www.ncbi.nlm.nih.gov/pmc/articles/PMC7092803/ doi:10.1056/NEJMOA2001017 (Scholia)
  4. Federhen S. The NCBI Taxonomy database. NAR. 2012 Jan;40(Database issue):D136-43. doi:10.1093/NAR/GKR1178 (Scholia)