Os coronavírus, como grupo, não são novos, e alguns deles são um tanto quanto inofensivos. Por exemplo, os coronavírus humanos HCoV-229E e HCoV-OC43 normalmente causam apenas resultado um resfriado comum [1]. Por outro lado, para os coronavirus relacionados ao vírus da SARS isso é diferente. Entre eles encontra-se o SARS-CoV-2, claro, que é o tema principal deste livro [2].
O virus SARS-CoV-2 não é o primeiro coronavirus (CoV). De fato, se conhecem muitos coronavírus relacionados com o vírus da SARS, como se meciona nesta Lista de taxonomia do NCBI.
Primeiro enumeramos todos os virus SARSr-CoV no Wikidata:
SPARQL sparql/allSARSCoVViruses.rq (run, edit)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q278567 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
Isso nos dá:
Se compararmos essa lista com a da seção 2.2, elas não se sobrepõe completamente.
Para a pandemia atual, os sete coronavírus humanos podem ser de interesse particular [3].
Podemos usar essa busca para enumerá-los:
SPARQL sparql/humanCoronaviruses.rq (run, edit)
SELECT ?virus ?virusLabel ?ncbi WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
Isso nos dá um bom ponto de partida para estudá-los:
Mas todos os coronavírus relacionados com o SARS são só um dos subgrupos. Outro subgrupo (que inclui os relacionados a SARS) são os betacoronavirus:
SPARQL sparql/allBetacoronaViruses.rq (run, edit)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q16532287 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY ?virusLabel
Devido a abundância de dados sobre eles no Wikidata, preferimos fazer um gráfico de dependência:
SPARQL sparql/allBetacoronaVirusesGraph.rq (run, edit)
#defaultView:Graph
SELECT ?parent ?parentLabel ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q16532287 .
?virus wdt:P171 ?parent .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
Que fornece a seguinte saída:
A lista completa de coronavírus se vê aqui:
SPARQL sparql/allCoronaViruses.rq (run, edit)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q57751738 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY ASC(?virus)
Novamente, optamos por fazer um gráfico de dependência:
SPARQL sparql/allCoronaVirusesGraph.rq (run, edit)
#defaultView:Graph
SELECT ?parent ?parentLabel ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q57751738 .
?virus wdt:P171 ?parent .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
} ORDER BY ASC(?parent) ASC(?virus)
Isso nos dá a seguinte saída:
Também podemos consultar artigos que comparem um coronavírus humano com outros coronavírus.
SPARQL sparql/compareViruses.rq (run, edit)
SELECT DISTINCT ?virus ?virusLabel ?work ?workLabel WITH {
SELECT DISTINCT ?virus ?virus2 ?work WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?virus2 wdt:P171+ wd:Q57751738 .
?work wdt:P921 ?virus, ?virus2 .
FILTER ( ?virus != ?virus2 )
}
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
ORDER BY ?virusLabel ?virus ?workLabel ?work
Para os coronavírus, podemos enumerar os identificadores do NCBI Taxonomy [4] com:
SPARQL sparql/allSARSCoVVirusesTaxonomy.rq (run, edit)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q278567 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "pt,en". }
}
Isso nos dá: