コロナウイルスは新しいものではなく、その仲間には全く危険ではないものもあります。 たとえば、ヒトコロナウイルスHCoV-229EおよびHCoV-OC43は通常よくある風邪[1]を引き起こします。しかし、重症急性呼吸器症候群に関連するコロナウイルス（SARSrウイルス）は異なります。そしてSRAS-CoV-2が本文書[2]のメイントピックです。
SARS-CoV-2ウイルスは最初のコロナウイルス(CoV)ではありません。 実は、非常に多くのSARS関連CoVが知られています。 それは、このNCBI Taxonomyリストを見れば明らかです。
それでは最初にWikidataに収められている全てのSARSr-CoVウイルスをリストアップしてみましょう。
SPARQL sparql/allSARSCoVViruses.rq (実行, 編集)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q278567 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
}
結果は以下の通りになります。
この結果を2.2章の結果と比較すれば、それらが完全には一致しないことが分かります。
しかし、現在のパンデミックにおいては、7つのヒトコロナウイルスが特に関心を集めるでしょう[3]。 以下のクエリでこれらだけを取得できます。
SPARQL sparql/humanCoronaviruses.rq (実行, 編集)
SELECT ?virus ?virusLabel ?ncbi WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
}
より詳しくこれらのウイルスについて研究を始める際にこの結果は役立つことでしょう。
| virus | ncbi |
| SARS関連コロナウイルス (edit) | 694009 |
| SARS関連コロナウイルス (edit) | 227859 |
| MERSコロナウイルス (edit) | 1335626 |
| ヒトコロナウイルスNL63 (edit) | 277944 |
| ヒトコロナウイルス229E (edit) | 11137 |
| ヒトコロナウイルスHKU1 (edit) | 290028 |
| ベータコロナウイルス１ (edit) | 31631 |
| SARSコロナウイルス2 (edit) | 2697049 |
しかし、SARS関連のコロナウイルスは一つのサブグループに過ぎず、もう一つのコロナウイルスのサブグループとしてベータコロナウイルスがあります。
SPARQL sparql/allBetacoronaViruses.rq (実行, 編集)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q16532287 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
} ORDER BY ?virusLabel
Wikidataには非常に多くのメンバーが収められているので、グラフを用いてそれを可視化しましょう。
SPARQL sparql/allBetacoronaVirusesGraph.rq (実行, 編集)
#defaultView:Graph
SELECT ?parent ?parentLabel ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q16532287 .
?virus wdt:P171 ?parent .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
}
結果は以下の通りです。
全てのコロナウイルスのリストはこのようになります。
SPARQL sparql/allCoronaViruses.rq (実行, 編集)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q57751738 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
} ORDER BY ASC(?virus)
再び、グラフを用いて可視化します。
SPARQL sparql/allCoronaVirusesGraph.rq (実行, 編集)
#defaultView:Graph
SELECT ?parent ?parentLabel ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q57751738 .
?virus wdt:P171 ?parent .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
} ORDER BY ASC(?parent) ASC(?virus)
結果は以下の通りです。
ヒトコロナウイルスと、他のコロナウイルスを比較研究している論文を取得します。
SPARQL sparql/compareViruses.rq (実行, 編集)
SELECT DISTINCT ?virus ?virusLabel ?work ?workLabel WITH {
SELECT DISTINCT ?virus ?virus2 ?work WHERE {
VALUES ?virus {
wd:Q82069695 # SARS-CoV-2
wd:Q16983360 # HKU1
wd:Q16991954 # OC43
wd:Q8351095 # NL63
wd:Q16983356 # 229E
wd:Q4902157 # MERS-CoV
wd:Q278567 # SARS-CoV
}
?virus2 wdt:P171+ wd:Q57751738 .
?work wdt:P921 ?virus, ?virus2 .
FILTER ( ?virus != ?virus2 )
}
} AS %ARTICLES WHERE {
INCLUDE %ARTICLES
SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
}
ORDER BY ?virusLabel ?virus ?workLabel ?work
コロナウイルスについて、NCBI Taxonomy [4]識別子のリストを取得します。
SPARQL sparql/allSARSCoVVirusesTaxonomy.rq (実行, 編集)
SELECT ?virus ?virusLabel ?ncbi WHERE {
?virus wdt:P171+ wd:Q278567 .
OPTIONAL { ?virus wdt:P685 ?ncbi }
SERVICE wikibase:label { bd:serviceParam wikibase:language "ja,en". }
}
結果は以下の通りです。